Disable skipping for a set amount of time? [Solved]

[Cherrylin]

Hello everyone!

I've been looking around for a solution for this problem, and frankly, none to be found. All issues that were slightly similar doesn't seem to be anything I can stuff on my particular issue, so I thought of asking here myself.

I have a part of text that shows with a bit of transition and all, but this is perfectly skippable as it is now, and I don't want that. The reader should not be able to skip this at all. I tried using

Code: Select all

$ renpy.pause(0.5, hard='True')

- and while that does disable the person from clicking through it, it does kill the transition effects apparently...

What I'm looking for, or at least think I'm looking for is either;

A: A line that disables clicking (or advancing through clicking) until another line enables this again.
B: A line that disables clicking (or advancing through clicking) during a set amount of time, but the text will auto-advance as it should.

[Donmai]

What transition are you using? Many transitions can be safely subtituted by ATL transforms that interact better with hard pauses.

[Cherrylin]

Dissolve and Pause.

Basically, black screen, text fades in, stays there a bit, fades out.
I just have to disable the player from skipping that though. >w<;

[Asceai]

Yep, that's quite easy to do with ATL.

Code: Select all

scene expression Solid("#000")
show expression Text("It was a dark and stormy night.", size=24) at truecenter:
    alpha 0.0
    linear 4.0 alpha 1.0
    pause 12.0
    linear 4.0 alpha 0.0
$ renpy.pause(20.0, hard=True)

[Taleweaver]

Ren'Py questions go into the Ren'Py Questions forum.

Moving.

[Cherrylin]

@Taleweaver; Oh, sorry about that!! Thanks for moving it! :3

@Asceai; Thanks! It works for one line, however, if I try to do multiple lines, they show up at the same time (which is not what they should do). I tried a few different ways but they all give the same result.

Code: Select all

 scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(6.0, hard=True)

Code: Select all

 scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(3.0, hard=True)
    
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(3.0, hard=True)

Code: Select all

 scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(3.0, hard=True)
    
    scene expression Solid("#000")
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(3.0, hard=True)

How can I get the text to change after the pause? Is there a way to "end" the expression?
I'm still new to Ren'Py ^^; So sorry if this is a pretty noobish question.

Edit Okay it seems I did find a bit of a solution, so now my question is more if there's a better solution... xD;;

Code: Select all

    scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(4.0, hard=True)
    with Pause(4.0)
    
    scene expression Solid("#000")
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(4.0, hard=True)
    with Pause(4.0)

[Asceai]

How can I get the text to change after the pause? Is there a way to "end" the expression?

I dunno what the best way of doing that is, but you could toss in a with None.

Code: Select all

    scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(6.0, hard=True)
    with None
    scene expression Solid("#000")
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(6.0, hard=True)
    with None

EDIT: Oh, renpy.pause already has a mechanism for that. That must mean it's the right thing to do!

Code: Select all

    scene expression Solid("#000")
    show expression Text("It was a dark and stormy night.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(6.0, hard=True, with_none=True)
    scene expression Solid("#000")
    show expression Text("And all the cookies were eaten.", size=24) at truecenter:
        alpha 0.0
        linear 2.0 alpha 1.0
        pause 2.0
        linear 2.0 alpha 0.0
    $ renpy.pause(6.0, hard=True, with_none=True)

[Cherrylin]

Thank you, Asceai! It works perfectly! :3