Need help with Preferences Screen

[Tsuna]

Hi, please help me with this small problem.

How can I make the boxes become narrower? It's too wide



Thanks for helping.

[OokamiKasumi]

Hi, please help me with this small problem.
-- How can I make the boxes become narrower? It's too wide

What is your game size: 1280x760, 1366x768 or something else?

For a 1280x760 screen size...
Go to screens.rpy and add this at the bottom of screen preferences:

Code: Select all

################################ 
init -2:
    ## -------- grid --------------
    style prefs_grid:
        ypos 0.15 #How far over to the right. 
        xmaximum 900 #Max width for whole grid. 
        xalign 0.5 #Center

    ## ------- frame --------------
    style pref_frame:
        # background Frame("ui/frame.png",10,10) #If you have your own. 
        xfill True
        xmargin 3
        ymargin 3
        top_margin 5

    ## -------- vbox ---------------
    style pref_vbox:
        xfill True
        top_margin 75

    ## -----------------------------
    style soundtest_button:
        xalign 0.5 #Center the button
        
    ## ----- Label ------------------
    style pref_label:
        xalign 0.5 # center

It looks like this:

Note!
-- To make your Navigation Horizontal at the bottom:

Code: Select all

screen navigation:

    # The background of the game menu.
    window:
        style "gm_root"

    # The various buttons.
    frame:
        style_group "gm_nav"
        xalign .50
        yalign .98

        has hbox # Instead of vbox!

        textbutton _("Return") action Return()
        textbutton _("Settings") action ShowMenu("preferences")
        textbutton _("Save") action ShowMenu("save")
        textbutton _("LoadSaved") action ShowMenu("load")
        textbutton _("MainMenu") action MainMenu()
        textbutton _("Help") action Help()
        textbutton _("Quit") action Quit()

init -2:

    # Make all game menu navigation buttons the same size.
    style gm_nav_button:
        size_group "gm_nav"

To add a Label at the top of the Prefs screen, add this:

Code: Select all

screen preferences:
    tag menu
    use navigation

    frame:
        style_group "pref"
        xfill True
        has vbox
        label _("Game Settings?")