Buttons in Edgescroll screen help

[valentin]

Hello, so I wanted to eventually make a map screen that uses edge scroll and image buttons. You put your mouse to the edge and as it scrolls you can see the various places you can click on. I was just testing out the code, and I can't figure out why it wouldn't work. Here's what I had:

Code: Select all

screen edgescroll_screen:
    viewport:
        edgescroll (100, 500)
        add "bg/forest/sun_thru_trees.jpg" at truecenter
        
        vbox:
                xpos 100
                ypos 200
                textbutton _("Test"):
                   action Return(True)
       
call screen edgescroll_screen

The edge scroll works fine until I put the vbox in. If the vbox code is there, it won't scroll. If just the text button code is there, I receive an error like viewport doesn't accept this action or something. Is what I'm trying to do not possible?

[Milkymalk]

The problem here is the indentation. Make vbox a child of the screen, not the viewport:

Code: Select all

screen edgescroll_screen:
    viewport:
        edgescroll (100, 500)
        add "bg/forest/sun_thru_trees.jpg" at truecenter
       
    vbox:
        xpos 100
        ypos 200
        textbutton _("Test"):
           action Return(True)
       
call screen edgescroll_screen

[valentin]

I tried that, but when I do that, the button doesn't scroll with the image.

[Milkymalk]

I tried that, but when I do that, the button doesn't scroll with the image.

OK, I understand what you want now.

Blind guessing now. I'd try:

Code: Select all

screen edgescroll_screen:
    viewport:
        edgescroll (100, 500)
        add "bg/forest/sun_thru_trees.jpg" at truecenter
        textbutton "Test" xpos 100 ypos 200 action Return(True)
       
call screen edgescroll_screen

[PyTom]

So, the issue here is that when you put two things inside a viewport, Ren'Py creates a Fixed to put them in. That Fixed is the size of the screen, which is too small to contain everything inside the viewport.

I'd suggest that what you want is the child_size argument to viewport:

Code: Select all

screen edgescroll_screen:
    viewport:
        child_size (1024, 1024) # size of sun_thru_trees.jpg
        edgescroll (100, 500)
        add "bg/forest/sun_thru_trees.jpg"
        textbutton "Test" xpos 100 ypos 200 action Return(True)
       
call screen edgescroll_screen

[valentin]

Thank you to you both, I'll try your suggestions.