Showing two screens at the same time? [SOLVED]

[AsHLeX]

So basically I have an imagemap and an imagebutton which calls an information screen in-game (that doesn't cover up the whole screen)

Imagemap:

Code: Select all

# Bedroom
screen weekday_morning:
    key "dismiss" action [[]]
    imagemap:
        ground "BG/Hiro's Bedroom.png"
        hover "BG/Hiro's Bedroom w.png"
        
        hotspot (192,375,100,100) clicked Jump("sleep_in")
        hotspot (409,482,100,100) clicked Jump("morning_out")

Imagebutton:

Code: Select all

screen open_information:
    vbox xalign 1.0 yalign 0.0:
        textbutton "Stats" action Show("aff_screen")

Information Screen:

Code: Select all

screen aff_screen:
    frame:
        yalign 0.0
        xalign 0.5
        vbox:
            label "Statistics" xalign 0.5
            hbox:
                label "Intelligence" xminimum 150
                bar range int_max value int_pt xmaximum 400
            hbox:
                label "Fitness" xminimum 150
                bar range fit_max value fit_pt xmaximum 400
            hbox:
                label "Social" xminimum 150
                bar range soc_max value soc_pt xmaximum 400
            hbox:
                label "Art" xminimum 150
                bar range art_max value art_pt xmaximum 400
            hbox:
                label "Stress" xminimum 150
                bar range stress_max value stress_pt xmaximum 400
            hbox:
                xalign 0.5
                textbutton "{size=18}Return{/size}" action Hide("aff_screen")

Code: Select all

label start:
    show screen weekday_morning 
    show screen open_information
    return

but doing this won't work because the game will just return to the main menu again.
But if I call the screen weekday_morning, then it will be over the screen open_information (meaning I can't see the imagebutton.)

Can anyone point me in the right direction, please?

Thanks for reading ^_^
And thank you in advance. ^^"

[orz]

"show" simply displays the screen. It doesn't wait before moving on.

So what's happening there is it puts up the first screen quickly, then also puts up the second screen at the same time, then hits the return and exits to main menu before you notice it.

If you use "call" it'll wait for input, however.

[AsHLeX]

But if i use call one screen will override the other. And I'll only have 1 screen

[trooper6]

You could try having the first screen use the second screen and see if that works.
Use is a keyword documented here: http://www.renpy.org/doc/html/screens.html#use
I have used use before and it works well...mostly in my main menu screen...you know, if they've completed the game use this extra screen with extra secret buttons.

I'm on my iPad so I can't build a test example, but you could try that out.

[orz]

You could also try using "show" on the first screen and using "call" on the second screen so it stops for input there.

Just make sure the second screen being called is "modal False" so you can click on the other screen.

So in essence what will happen is the first screen is called, like a transparent sheet, and the second screen is laid right on top of the first one. Then the program waits for input.

[Alera]

Just another suggestion but what about using ui.interact? That way you can show as many screens as you want and this will prevent the player from being able to simply click and skip the screens.


Something like this:

Code: Select all

label start:
    show screen weekday_morning 
    show screen open_information
    python:
        ui.interact()
    return

[AsHLeX]

Solved!! Thank you so much trooper6, orz and Alera!!