%(money)d display in inventory

[Bartulisica]

In dialogue, I can show my "money" value with %(money)d command, but if I want to add the same text to inventory
screen, it just says "You have %(money)d". Literally.
What seems to be the problem here. Money not defined in the right place? Coz I define it after label start, and inv_screen is defined before. How to fix this?
And, how to show item list? %(items)d isn't working as well. ( $ items = [])

Code: Select all

screen inv_screen:
             frame:
                 vbox:
                      text "Inventory: "
                      text "You have %(money)d"

I know I have so much questions, but I'm pretty new to Ren'Py, and even though I get the basics, and I know enough to make a simple VN, I want to explore more.

Thanks in advance.

[mobychan]

Code: Select all

screen inv_screen:
    frame:
        vbox:
            text "Inventory: "
            text "You have %d" % (money)

this should do the trick

since your items variable is an array you need to loop that array and add each item as text:

Code: Select all

for item in items:
    text item

[trooper6]

Renpy text interpolation uses brackets, so as long as you are in a Renpy line rather than a python line, you don't have to use %

Here is an inventory screen that I made as an example for someone else that shows both an individual variable and a list:

Code: Select all

default gold = 100
default items = ["rope", "dagger", "chewing gum"]

screen inventory_screen():
    vbox:
        align (0.9, 0.0)
        text "Inventory:"
        text "_____"
        text "Gold Pieces: [gold]"
        for item in items:
            text "[item]"

label start:
    show inventory_screen()
    "You should see your inventory in the upper right corner."

[Dylan]

Instead of writing $ in front of the variables instead type define so it looks something like this (borrowing your example mobychan):

Code: Select all

define items = ["apple", "phone"]
define money = 0

##########
screen inv_screen:
    frame:
        vbox:
            text "Inventory: "
            text "You have %d" % (money)
            for item in items:
                text item
        
    
# The game starts here.
label start:
    show screen inv_screen()
    "Menu screen on top left."
    "End game."
    return

trooper6, you forgot to put "screen" for "show screen"

Code: Select all

label start:
    show screen inventory_screen()
    "You should see your inventory in the upper right corner."

[Bartulisica]

@ mobychan : I tried to do so before I posted the question, and it didn't work..

But, thanks all of you!

[trooper6]

Instead of writing $ in front of the variables instead type define so it looks something like this (borrowing your example mobychan):

Code: Select all

define items = ["apple", "phone"]
define money = 0

not define, default

It should be
default items = ["apple", "phone"]

trooper6, you forgot to put "screen" for "show screen"

So I did! Thanks for catching that error!

[Dylan]

Thanks, didn't realize there was a difference since I was getting the same output.
Guess I need to re-read the documentation a bit more thoroughly.

[trooper6]

Default and define are both described one after another here: http://www.renpy.org/doc/html/python.ht ... -statement

The seem very similar and I think PyTom would have to explain all the differences. What I'd say is that I've generally seen define used primarily with characters...which don't change after init. On the other hand, I see default used for variables that are changed during the course of the game.

[PyTom]

Bracket interpolation is now always preferred to %(whatever)d interpolation, which has been left around to support legacy code. Bracket interpolation works everywhere text does, and code like:

Code: Select all

text "Hello, [planet]."

is much faster than

Code: Select all

text "Hello, %s." % planet

since it can be more easily analyzed by Ren'Py.