Lemma Soft Forums

init -1 python:
   
    class Fighter():
        def __init__(self, name, max_hp, max_mp, skills):
            self.name = name
            self.max_hp = max_hp
            self.hp = max_hp
            self.max_mp = max_mp
            self.mp = max_mp
            self.skills = skills
               
        def auto_select(self):
            while True:
                selected = renpy.random.choice(self.skills)
                if selected.cost<self.mp:
                    return selected
           
        def defence(self):
            if user.skill.hit<renpy.random.randint (0,100):
                narrator ("%s dodged the attack" %self.name)
                return
            else:
                self.hp -= user.skill.power
                narrator ("%s got %d damage" %(self.name, user.skill.power))
                return
           
    class Skill():
        def __init__(self, name, cost, hit, power):
            self.name = name
            self.cost = cost
            self.hit = hit
            self.power = power
           
        def use(self):
            user.mp -= self.cost
            narrator ("%s used %s" %(user.name, self.name))
            target.defence()
            return
           
    def battle(win, lose):
        global player, enemy, user, target
        renpy.show_screen("battle_ui")
        while True:
            renpy.say (narrator, "Skill select", interact=False)
            player.skill = renpy.call_screen("skill_select")
            enemy.skill = enemy.auto_select()
            user = player
            target = enemy
            user.skill.use()
            if target.hp<1:
                renpy.jump(win)
            user = enemy
            target = player
            user.skill.use()
            if target.hp<1:
                renpy.jump(lose)
                                           
screen skill_select:   
    vbox xpos .05 ypos .3:
        for i in player.skills:
            if i.cost <= player.mp:
                textbutton "[i.name]" action Return (value=i)
            else:
                textbutton "[i.name]"

screen battle_ui:   
    frame xmaximum 200 xanchor 1.0 xpos 0.99 yalign 0.02:
        has vbox
        hbox:
            text "[player.name]"
        hbox xfill True:
            text "HP"
            text "[player.hp]/[player.max_hp]" xalign 1.0
        hbox xfill True:
            text "MP"
            text "[player.mp]/[player.max_mp]" xalign 1.0
           
    frame xmaximum 200 xpos 0.01 yalign 0.02:
        has vbox
        hbox:
            text "[enemy.name]"
        hbox xfill True:
            text "HP"
            text "[enemy.hp]/[enemy.max_hp]" xalign 1.0
        hbox xfill True:
            text "MP"
            text "[enemy.mp]/[enemy.max_mp]" xalign 1.0
           
##############################################################################
# sample game script

label start:
    $ Slash = Skill("Slash", 0, 60, 10)
    $ Magic = Skill("Magic", 25, 70, 20)
    $ player = Fighter ("Hero", 50, 50, [Slash, Magic])
    $ enemy = Fighter ("Monster", 50, 50, [Slash, Magic])
    $ battle("win", "lose")
   
label win:
    "you won"
    return
   
label lose:
    "you lost"
    return