Is the wipeleft Transition Irrationally Slow?

[papiersam]

Code: Select all

label start:
    
    call screen a
           
screen a:
    
    add "#fff"
    textbutton "Menu" action Show('b', transition=wiperight)
    
screen b:
    frame:
        xsize 300
        yalign 1.0
        background "#000"    
    textbutton "Map" action Hide('b', transition=wipeleft)

Is the wipeleft delaying for anyone else? Because the other ones aren't, but wipeleft waits for a moment before running. Experienced on the current version of Renpy (6.99.12).

[Imperf3kt]

Happening here too, on the previous release. It appears to be taking about a second before the button responds.

[papiersam]

Okay, testing the code above and looking closely, you can see a 1 pixel black line sweep the screen until it reaches the frame. So the delay in this case is the time it takes for the transition to reach any non-transparent objects.

Addendum: how do we side-step this?

[PyTom]

Honestly, your best bet is to just use a transform:

Code: Select all

label start:

    call screen a

    return

screen a:

    add "#fff"
    textbutton "Menu" action Show('b')

screen b:
    frame:
        at btransform
        xsize 300
        yalign 1.0
        background "#000"
    textbutton "Map" action Hide('b')


transform btransform:
    on show:
        offscreenleft
        linear .5 left

    on hide:
        linear .5 offscreenleft