Android-compatible Keyboard Screen

[qirien]

So one of the few things that doesn't port over to android is the input function (like for typing in a name). So here's a screen you can include if you would like to automatically use an on-screen keyboard for renpy.input. (based off of shuen's android keyboard, but using screen language and styles). Here's what it looks like:

To test it, click on "Android" in Ren'Py and then under Emulation choose Phone or Tablet. You can call it the same way you use regular renpy.input, like this:

Code: Select all

    $ his_name = renpy.input("What is your name?")
    "You picked the name [his_name]."

And here's the screen code (you might want to put it in its own file, like inputter.rpy).

Code: Select all

########################################################
#   Android keyboard input
init python:
    text_list1=[["Q","W","E","R","T","Y","U","I","O","P"],
                ["A","S","D","F","G","H","J","K","L"],
                ["Z","X","C","V","B","N","M"]]
    text_list2=[["q","w","e","r","t","y","u","i","o","p"],
                ["a","s","d","f","g","h","j","k","l"],
                ["z","x","c","v","b","n","m"]]
    input_text = ""
    text_list=text_list1
    text_group=1
    initial_caps=True
    caps_lock = False
    
style inputter_text:
    size 30
    
style inputter_button_text:
    size 30
    
style inputter_keys:
    size 40    

# Screen that Ren'Py will use for input if we are using a touch screen
screen input(prompt):
    variant "touch"    
    default caps_lock = False
    default input_text = ""
    if initial_caps:
        $ caps_lock = True
        $ initial_caps = False
    if caps_lock:
        $text_list=text_list1
    else:
        $text_list=text_list2
         
    frame:
        style_group "inputter"        
        xpos 0.5
        ypos 0.1
        xanchor 0.5
        yanchor 0
        xminimum 450

        vbox:
            $ display_text = prompt+"\n"+input_text
            text display_text
            text ""
            hbox:
                xalign 0.5
                textbutton "Backspace" action SetScreenVariable("input_text", input_text[:-1])
                textbutton "Delete all" action [ SetScreenVariable("input_text", ""),
                                                 SetScreenVariable("initial_caps", True) ]
                if (not caps_lock):
                    textbutton "Caps (On)" action SetScreenVariable("caps_lock", True)
                else:
                    textbutton "Caps (Off)" action SetScreenVariable("caps_lock", False)
            text ""
            vbox:
                xalign 0.5
                for text_row in text_list:
                    hbox:
                        xalign 0.5
                        for text_code in text_row:
                            textbutton text_code text_style "inputter_keys" action [ SetScreenVariable("input_text", input_text + text_code),
                                                          SetScreenVariable("caps_lock", False) ]
                text ""
                textbutton "Done" xalign 0.5 action Return(input_text)

[xavimat]

Thanks, qirien!
May I suggest something?
Screen language allows to define variants for touch screens, etc. You could use the same name "input" for your screen instead of "inputter", and the variable "prompt", instead of "input_header". This way, Ren'Py uses the correct screen and there is no need for the "if" statement in the script:

Code: Select all

# definition of your screen:
screen input(prompt):
    variant "touch"

    # change this line:
    #$ display_text = input_header+" "+input_text
    # to
    $ display_text = prompt+"\n"+input_text

In your script: $ his_name = renpy.input("What is your name?", "Jack", length=20) will choose the screen according to the device (the default value "Jack" and the maximum length won't be used, but maybe they could be included too).

[qirien]

Thanks, xavimat! I wasn't sure how to use "variant", so I appreciate you showing me that; it's much more elegant that way. I've changed the code above, also.

[PyTom]

This is very nice, but I added support for the Android keyboard on new years. It's in the nightly, and will be in the next release.

[qirien]

Alright, you're light years ahead of me as usual. Thanks, Tom.