Mark chosen choices

[Moshibit]

An important part of the visual novels are the choices, I consider that the player has the right to know which choices he has already chosen. Here is a simple script to change the text color of the chosen choices in a viusal novel. Modify the screens.rpy script

Code: Select all

screen choice(items):
    style_prefix "choice"

    vbox:
        for i in items:
            textbutton i.caption action i.action: # edit this line
                if i.chosen == True: # add this line
                    style "choice_chosen_button" # add this line


define config.narrator_menu = True


style choice_vbox is vbox
style choice_button is button
style choice_button_text is button_text

style choice_chosen_button is choice_button # add this line
style choice_chosen_button_text is choice_button_text # add this line

style choice_vbox:
    xalign 0.5
    ypos 270
    yanchor 0.5

    spacing gui.choice_spacing

style choice_button is default:
    properties gui.button_properties("choice_button")

style choice_button_text is default:
    properties gui.button_text_properties("choice_button")

style choice_chosen_button_text: # add this line
    idle_color "#f00" # add this line

The following script will add an image to the chosen choices. It is very simple but gives an idea of how to do it. It can be improved if you know about screen language.

Code: Select all

screen choice(items):
    style_prefix "choice"

    vbox:
        for i in items:
            hbox: # add this line
                textbutton i.caption action i.action # edit this line
                if i.chosen == True: # add this line
                    add "gui/choise_mark.png" # add this line. Recommended size 30*30 pixels


define config.narrator_menu = True


style choice_vbox is vbox
style choice_button is button
style choice_button_text is button_text

style choice_vbox:
    xalign 0.5
    ypos 270
    yanchor 0.5

    spacing gui.choice_spacing

style choice_button is default:
    properties gui.button_properties("choice_button")

style choice_button_text is default:
    properties gui.button_text_properties("choice_button")

I hope these examples are helpful.

[RicharDann]

Pretty good, I was thinking on a really roundabout way to do this but it is actually so simple! Thank you for sharing this, you've saved me a lot of work.

[Tiger Lyz]

Thanks! It's really usefull.