silly question

[Matt_D]

I'm sure this is either a: impossible (or just way to difficult for me to think about) or b: really easy and asked a million times.

However the search forum facility has given me little luck accursed beastie.

I don't like repeating myself, it's annoying and wasteful, I'll do it if needs must but if there is a way out ooo baby I wanna take it

I'm gonna be using this alot

Code: Select all

    show expression Text('-=1=-',size=50,yalign=0.5, xalign=0.5, drop_shadow=(2,2)) as text
    with dissolve
    with Pause(1)
    
    hide text
    with dissolve

except replace the '-=1=-' with any number of other short things.

is there a way I can just make a function to save my ctrl+c ctrl+v??

[Adorya]

Nvm misunderstood the question :p

You could try to declare an int then increment it, but it would still remain the same, you have to type the increment...or with third party software it is possible to create incremented text (Excel macro, etc...)

[Jake]

I'm sure this is either a: impossible (or just way to difficult for me to think about) or b: really easy and asked a million times.

I'm possibly just missing something really obvious, but I don't think it's either of those, really. I think it's more likely c: possible, but requiring some understanding of i) how Ren'Py works past the ren'py-script and ii) Python. Maybe that comes under the first option...

My understanding of both of those things comes under the heading of 'working, but flawed', so I'm probably missing something really obvious that would make this easier, but I came up with the following which at least works...

Put this code inside an init block:

Code: Select all

    python:
        
        renpy.store.centreTextValue = "-"
        
        def centreText(st, at):
            return Text(renpy.store.centreTextValue,size=50,yalign=0.5, xalign=0.5, drop_shadow=(2,2)), None
    
        def showCentreText(text, pauseTime = 1.0):
            renpy.store.centreTextValue = text
            renpy.show('centreTextDisplayable')
            renpy.with(dissolve)
            renpy.pause(pauseTime)
            renpy.hide('centreTextDisplayable')
            renpy.with(dissolve)
        
    image centreTextDisplayable = DynamicDisplayable(centreText)

Then call it in your script like this:

Code: Select all

    e "Hey, let's have some text appearing right in the middle of the screen!"
    
    $ showCentreText("Some Text")

    e "Yeah, just like that!"
    
    $ showCentreText("Just Like That", 5.0)
    
    e "... Okay, that one lasted too long."

I'm sure I've directly 'show'ed a Displayable before, which would make this a lot simpler and less hacky, but I can't remember how...

[Matt_D]

Brilliant, and even better I see how and why it works woohoo. I don't mind if it's hacky it works just fine. Cheers.

[PyTom]

You can use the 'what' parameter to show to eliminate the need for a DynamicDisplayable:

Code: Select all

init:
  python:   
        def showCentreText(text, pauseTime = 1.0):
            renpy.show('centreTextDisplayable', what=Text(renpy.store.centreTextValue,size=50,yalign=0.5, xalign=0.5, drop_shadow=(2,2)))
            renpy.with(dissolve)
            renpy.pause(pauseTime)
            renpy.hide('centreTextDisplayable')
            renpy.with(dissolve)

Other then that, everything looks good.

[Jake]

You can use the 'what' parameter to show to eliminate the need for a DynamicDisplayable:

Code: Select all

...

You mean:

Code: Select all

       def showCentreText(text, pauseTime = 1.0): 
            renpy.show('centreTextDisplayable', what=Text(text,size=50,yalign=0.5, xalign=0.5, drop_shadow=(2,2))) 
            renpy.with(dissolve) 
            renpy.pause(pauseTime) 
            renpy.hide('centreTextDisplayable') 
            renpy.with(dissolve)

(renpy.store.centreTextValue isn't set; first param to Text() should be the param passed into the function)

But yeah, that seems to work. I could have sworn I'd tried exactly that earlier and been told "no image with the name 'centreTextDisplayable' could be found". I guess I must have been doing something wrong... I concluded from that that I'd need to have a labelled displayable to work with, hence using the DynamicDisplayable. Not having to pass the text via a global is certainly a lot less hacky!