[Solved] Long transition while user clicks through dialog?

[PatchyDoll]

I am trying to create a very slow transition that happens in the background while the player clicks through dialog text. I figured out how to make the window stay up during transitions using "window show", however I don't know how to make the transition happen "in the background" instead of interrupting dialog. The transition itself is a slow dissolve (more than 4 seconds long) of both the background and characters. Any help is really appreciated!

[SundownKid]

You could make overlaid versions of all the stages of the transition in Photoshop and then switch between those after every new text block. Basically switching between, say, 4 gradual images instead of 2 non-overlaid images.

[PatchyDoll]

You could make overlaid versions of all the stages of the transition in Photoshop and then switch between those after every new text block. Basically switching between, say, 4 gradual images instead of 2 non-overlaid images.

That's one way to do it, but I see that as a last-resort hack. I know what I'm trying to do is possible, because it's been done in several other visual novels. Thanks for the suggestion. I'm looking online for applicable source code but haven't found any yet.

[SundownKid]

Alternatively you could make a screen, add the bottom layer below the top layer, and gradually reduce the opacity of the top layer image. I'm not sure if it works, but it SHOULD...

[PatchyDoll]

Interesting idea! I'll give that a try and see what I come up with.

[Alex]

ATL transforms should be the answer.

Code: Select all

transform my_dissolve:
    on show:
        alpha 0.0
        linear 4.0 alpha 1.0
    on hide:
        linear 4.0 alpha 0.0
    on replace:      # when new image appears
        alpha 0.0
        linear 4.0 alpha 1.0
    on replaced:     # when old image disappears
        linear 4.0 alpha 0.0
        
label start:
    
    scene black
    "Transitions are brake the dialog"
    show eileen normal at center
    with Dissolve(4.0)
    "Like this."

    "But ATL transforms..."
    show eileen normal at left, my_dissolve
    "... are not."
    "So, just create transform you need..."
    show eileen vhappy at right, my_dissolve
    "... and use it."
    "Should work."
    "...."

http://www.renpy.org/doc/html/atl.html

[PatchyDoll]

ATL transforms should be the answer.

That did the trick! I now have exactly what I wanted. Thank you so much!

[nyaatrap]

ATL transforms should be the answer.

Oh that it. I didn’t tested it, but it can be the ultimate answer to solve many problems existence transitions have