(Done)How to change the choice menu text color?

[edouardlicn]

Code: Select all

    style.menu_choice_text.hover_color = "#ffffff"
    style.menu_choice_text.idle_color = "#eaeaea"

Why codes above don't work.

[Alex]

Should be

Code: Select all

style.menu_choice.hover_color = "#ffffff"
style.menu_choice.idle_color = "#eaeaea"

[edouardlicn]

no,it dosen't work.

[Alex]

Hm, where did you put this code?
Try to add this lines at the end of init python block that is right after choice screen in screens.rpy. If it wouldn't work, then show the code you have to let people find the problem.

[edouardlicn]

I have post it on that place.

[Elmiwisa]

The code you have merely produce a style called menu_choice_text. Producing a style is not enough, you need to actually use it. Have you wrote the code to use it?

[edouardlicn]

Code: Select all

##############################################################################
# Choice
#
# Screen that's used to display in-game menus.
# http://www.renpy.org/doc/html/screen_special.html#choice

screen choice:

    window: 
        style "menu_window"        
        xalign 0.5
        yalign 0.5
        
        vbox:
            style "menu"
            spacing 2
            
            for caption, action, chosen in items:
                
                if action:  
                    
                    button:
                        action action
                        style "menu_choice_button"                        

                        text caption style "menu_choice"
                    
                else:
                    text caption style "menu_caption"

init -2 python:
    config.narrator_menu = True
    

    style.menu_choice.hover_color = "#ffffff"
    style.menu_choice.idle_color = "#eaeaea"
    style.menu_window.set_parent(style.default)
    style.menu_choice.set_parent(style.button_text)
    style.menu_choice.clear()
    style.menu_choice_button.set_parent(style.button)
    style.menu_choice_button.xminimum = int(config.screen_width * 0.55)
    style.menu_choice_button.xmaximum = int(config.screen_width * 0.55)
    
    style.menu_choice_button.background = Frame("ui/choice_bg_idle.png",28,9)
    style.menu_choice_button.hover_background = Frame("ui/choice_bg_hover.png",28,9)

And you can see what happen here http://pan.baidu.com/share/link?shareid ... 3172121467

[Elmiwisa]

Oh I see, so you put these line in the wrong position.
Notice this line:

Code: Select all

    style.menu_choice.clear()

This line clear all the attribute from the style, undoing any changes you made to it before that point, as stated here http://www.renpy.org/doc/html/style.html#Style.clear

Thus you need to put your code AFTER this line, as follow:

Code: Select all

init -2 python:
    config.narrator_menu = True
   

    style.menu_window.set_parent(style.default)
    style.menu_choice.set_parent(style.button_text)

    style.menu_choice.clear()                             #any changes need to be made after this line
    style.menu_choice.hover_color = "#ffffff"         #here is your code
    style.menu_choice.idle_color = "#eaeaea"

    style.menu_choice_button.set_parent(style.button)
    style.menu_choice_button.xminimum = int(config.screen_width * 0.55)
    style.menu_choice_button.xmaximum = int(config.screen_width * 0.55)
   
    style.menu_choice_button.background = Frame("ui/choice_bg_idle.png",28,9)
    style.menu_choice_button.hover_background = Frame("ui/choice_bg_hover.png",28,9)

[edouardlicn]

ok,it fixed