Remebering Selected Choices.

[ShippoK]

I was having a hard time finding any info on this so I'll just ask on the Q&A thread.

I was wondering if there was a simple way to have menu choices that a player made in a previous game be remember for the rest of the game.
Something along the lines of this.
Ex.


Here's the menu choice code if needed.

Code: Select all

    style.menu_choice_button.background = Frame("menuchoicevr.1.png",25,15)
    style.menu_choice_button.hover_background = Frame("menuchoicevr.2.png",25,15)
    style.menu_choice_button.yminimum = 40
    style.menu_choice_button.xminimum = 375

[SundownKid]

You could give each choice its own variable and then modify that choice depending on if it's true or false.

Code: Select all

menu:
  if persistent.choice1 == True:
     "{color=#EAF00}Do stuff{/color}":
        jump choice1
  else:
      "Do stuff":
         $ persistent.choice1 = True
         jump choice1

[Elmiwisa]

No need, Ren'Py do it for you. Except not completely.
Look at the code for the choice screen in screens.rpy. You will find this line:

Code: Select all

for caption, action, chosen in items:

A careful reading of the code will reveal that while variable caption and action will be referred to after this line, variable chosen is never used. That unused variable mark which choice have been made before, and is persistent. You simply need to modify the code to make use of this variable. Something like:

Code: Select all

if chosen:
    #one kind of button
else:
    #another kind of button

[ShippoK]

Thank you for the answers.

I'll probably do ShundownKid's method for now.
When I feel more comfortable with fiddling with the code Elmiwisa mentioned above, I'll try that one out as well.

[Elmiwisa]

Thank you for the answers.

I'll probably do ShundownKid's method for now.
When I feel more comfortable with fiddling with the code Elmiwisa mentioned above, I'll try that one out as well.

Uh, it's a pretty simple change that take less than 5 minutes, and once done it apply instantly to all menu. It's much less painful than doing it individually for each menu. I can't really tell you exactly how to make the change, because it depends on how you want your menu to look like. Though this is one simple way to do it:
Replace all the choice screen code with this:

Code: Select all

screen choice:

    window: 
        style "menu_window"        
        xalign 0.5
        yalign 0.5
        
        vbox:
            style "menu"
            spacing 2
            
            for caption, action, chosen in items:
                
                if action:  
                    if chosen:
                        button:
                            action action
                            style "menu_choice_chosen_button"                        

                            text caption style "menu_choice_chosen"
                    else:
                        button:
                            action action
                            style "menu_choice_button"                        

                            text caption style "menu_choice"
                    
                else:
                    text caption style "menu_caption"

Then just make your style for "menu_choice_chosen" and "menu_choice_chosen_button". Pretty simple change really, it's less than 20 extra lines from the original default Ren'Py code.
Beside, SundownKid's method don't even work. You need to modify it due to syntax error.