Save/Load screen irritating GUI problem.

[SadisticWonderland]

Tell me if topic like this had exist before. I'll happily go there.

I'm currently trying to design my own GUI and I encounter a little problem that irritates me when I try to change the GUI for the save/load screen. The screenshot taken is way too small compared to the save frame I created.

It become like this;

As you can see, the screenshot is way too small that it seriously irritate my eyes. Is there any ways to change it's size so that it will fit nicely in the frame box?

please and thank you.

And btw, this is the code I used;

Code: Select all

screen file_picker:

    frame:
        xpadding 0
        ypadding 0
        xalign 0.13
        yalign 0.74
        background None
        has vbox
        
        hbox:
            xalign 0.5
            spacing 13
            for i in range(1, 3):
                vbox:
                    spacing 18
                    button:
                        style "savebutton"
                        action [FileAction(i)]
                        key "save_delete" action [FileDelete(i)]
                        
                        
                        add FileScreenshot(i) xalign 0.5 yalign 0.5 


                        
                    $ description = "% 2s. %s\n%s" % (
                        FileSlotName(i, 2 * 2),
                        FileTime(i, empty=_("Empty Slot.")),
                        FileSaveName(i))
                    
                    text description size 15 xalign 0.6
                    
        hbox:
            xalign 0.5
            spacing 13
            for i in range(3, 5):
                vbox:
                    spacing 18
                    button:
                        style "savebutton"
                        action [FileAction(i)]
                        key "save_delete" action [FileDelete(i)]
                        
                        
                        add FileScreenshot(i) xalign 0.5 yalign 0.5 

                        
                    $ description = "% 2s. %s\n%s" % (
                        FileSlotName(i, 2 * 2),
                        FileTime(i, empty=_("Empty Slot.")),
                        FileSaveName(i))
                    
                    text description size 15 xalign 0.6
                    
        hbox:
            xalign 0.5
            
            textbutton _("Auto"):
                action FilePage("auto") style "savenavigation" yalign 0.94 
            null width 20

            textbutton _("Quick"):
                action FilePage("quick") style "savenavigation" yalign 0.94 
            null width 20

            for i in range(1, 9):
                textbutton str(i):
                    action FilePage(i) style "savenavigation" yalign 0.94
                null width 10
            null width 20
            
    imagebutton auto "ui/back_%s.png" action [FilePagePrevious()] xalign 0.09 yalign 0.94 style "savenavigation"
    imagebutton auto "ui/forward_%s.png" action [FilePageNext(max=8)] xalign 0.45 yalign 0.94 style "savenavigation"


screen save:

    use navigation
    use file_picker
    
    text "SAVE" xalign 0.3 yalign 0.2 size 34

screen load:

    tag menu

    use navigation
    use file_picker
    
    text "LOAD" xalign 0.3 yalign 0.2 size 34

init -2 python:
    style.file_picker_frame = Style(style.menu_frame)

    style.file_picker_nav_button = Style(style.small_button)
    style.file_picker_nav_button_text = Style(style.small_button_text)

    style.file_picker_button = Style(style.large_button)
    style.file_picker_text = Style(style.large_button_text)

    style.savebutton = Style(style.default)
    style.savebutton.insensitive_background = ("ui/save_bg.png")
    style.savebutton.idle_background = ("ui/save_bg.png")
    style.savebutton.hover_background = ("ui/save_bg.png")
    style.savebutton.xmaximum = 230
    style.savebutton.ymaximum = 170
    
    style.savenavigation = Style(style.default)
    style.savenavigation.background = None
    style.savenavigation_text.idle_color = "#000"
    style.savenavigation_text.hover_color = "#0066FF"
    style.savenavigation_text.selected_color = "#0066FF"

Help me. The too small screenshot irritate my bad eyesight. Thank you.

[akemicchi]

You can change the size of a screenshot with config.thumbnail_width and config.thumbnail_height.

Code: Select all

    config.thumbnail_width = 400
    config.thumbnail_height = 300

[PyTom]

Note that this only applies to new thumbnails, saved after you make the change.