[SOLVED]Show images above a screen?

[Alera]

I have a few screens and I get how to control the overlay of those with zorder but what about when I want to have an image to appear over them? More particular an image which is on a layer? The image is using a complex(for me) Python code so I don't know how to 'add' it under a screen so I could use zorder again and I'm pretty lost. I'll just post my code I guess, I hope you'll get what I'm trying to do?

Code: Select all

# Controls the movement of the image according to the mouse position using layers
init 800 python:
    class MouseParallax(renpy.Displayable):
        def __init__(self,layer_info):
            super(renpy.Displayable,self).__init__()
            self.xoffset,self.yoffset=0.0,0.0
            self.sort_layer=sorted(layer_info,reverse=True)
            cflayer=[]
            masteryet=False
            for m,n in self.sort_layer:
                if(not masteryet)and(m<0):
                    cflayer.append("master")
                    masteryet=True
                cflayer.append(n)
            if not masteryet:
                cflayer.append("master")
            cflayer.extend(["transient","screens","overlay"])
            config.layers=cflayer
            config.overlay_functions.append(self.overlay)
            return
        def render(self,width,height,st,at):
            return renpy.Render(width,height)
        def parallax(self,m):
            def trans(d,st,at):
                d.xoffset,d.yoffset=(int)(m*self.xoffset),0
                return 0
            return Transform(function=trans)
        def overlay(self):
            ui.add(self)
            for m,n in self.sort_layer:
                renpy.layer_at_list([self.parallax(m)],n)
            return
        def event(self,ev,x,y,st):
            import pygame
            if ev.type==pygame.MOUSEMOTION:
                self.xoffset,self.yoffset=((float)(x)/(config.screen_width))-0.5,((float)(y)/(config.screen_height))-0.5
            return
    MouseParallax([(100,"farback"),(50,"back"),(-80,"front"),(-280,"ontop")])

#screens
screen buttons:
    zorder 1
    vbox xalign 0.5 yalign 0.5:
        imagebutton auto "monster_%s.png" action ShowMenu('save') focus_mask True
       
# The game starts here.
label start:
    show bg
    show screen buttons 
    show zei onlayer ontop

It's probably a simple solution, but I just can't figure it out on my own. Help?

[KimiYoriBaka]

the first solution that comes to mind is to add a screen adds images based on a list, but I'm not sure if renpy's prediction would still work.

if you want to try that, it would be something like this:

Code: Select all

screen top_images:
    for i in imagelist:
        add i[0]:
            pos i[1]

label start:
    $ imagelist = [["zei.png", (0.5, 0.0)]]
    show bg
    show screen buttons
    show screen top_images

[Alera]

@KimiYoriBaka
Hmmm, strangely, with this my image doesn't show up at all. Or maybe I'm missing something? I don't get any errors. :'<

[KimiYoriBaka]

that's strange. did you try using zorder on the new screen as well?

[Alera]

Oh, I'm sorry I mislead you, I got it to display and zorder works, my mistake, but how do I make it so it so uses my layer? I want to use my mouse movement thing on it.

That code alone is still quite useful though, thank you~

[KimiYoriBaka]

Assuming I'm reading your code correctly, having images with parallax on top of the screens would require having another set of layers that are added to config.layers after the default ones.

if that is correct, then an adjustment like this would work:

Code: Select all

# Controls the movement of the image according to the mouse position using layers
init 800 python:
    class MouseParallax(renpy.Displayable):
        def __init__(self,layer_info, slayer_info):
            super(renpy.Displayable,self).__init__()
            self.xoffset,self.yoffset=0.0,0.0
            self.sort_layer=sorted(layer_info,reverse=True)
            self.sort_slayer=sorted(slayer_info,reverse=True) #repeating the same formatting
            cflayer=[]
            masteryet=False
            for m,n in self.sort_layer:
                if(not masteryet)and(m<0):
                    cflayer.append("master")
                    masteryet=True
                cflayer.append(n)
            if not masteryet:
                cflayer.append("master")
            cflayer.extend(["transient","screens","overlay"])
            for m,n in self.sort_slayer:
                cflayer.append(n)     #adding them after screens so they'll be rendered on top
            config.layers=cflayer
            config.overlay_functions.append(self.overlay)
            return
        def render(self,width,height,st,at):
            return renpy.Render(width,height)
        def parallax(self,m):
            def trans(d,st,at):
                d.xoffset,d.yoffset=(int)(m*self.xoffset),0
                return 0
            return Transform(function=trans)
        def overlay(self):
            ui.add(self)
            for m,n in self.sort_layer:
                renpy.layer_at_list([self.parallax(m)],n)
            for m,n in self.sort_slayer:
                renpy.layer_at_list([self.parallax(m)],n) #not sure, but it looks like this would be needed
            return
        def event(self,ev,x,y,st):
            import pygame
            if ev.type==pygame.MOUSEMOTION:
                self.xoffset,self.yoffset=((float)(x)/(config.screen_width))-0.5,((float)(y)/(config.screen_height))-0.5
            return
    MouseParallax([(100,"farback"),(50,"back"),(-80,"front"),(-280,"ontop")], [(100,"sfarback"), (0, "smaster"), (50,"sback"),(-80,"sfront"),(-280,"sontop")]) 
    #adding layers with identical values and a slight difference in name

#screens
screen buttons:
    zorder 1
    vbox xalign 0.5 yalign 0.5:
        imagebutton auto "monster_%s.png" action ShowMenu('save') focus_mask True
       
# The game starts here.
label start:
    show bg
    show screen buttons 
    show zei onlayer sontop  #adding to the layer on top of the screens

(disclaimer: I haven't tested this, and I'm just going off of how your code appears to work)

[Alera]

Wow, thank you!!! It finally worked!!! You're great >v<

[Friar Tuck]

Wow, thank you!!! It finally worked!!! You're great >v<

How does it work? Without a complete example, I do not understand. Please help me.

Oh, sorry. I see this: http://lemmasoft.renai.us/forums/viewto ... 38#p293811
Its geat!