Make options in menu unelectable/grayed out?

[Beckers]

I was wondering if there's a way to make menu options unclickable, but still appear/be visible? Help is appreciated, thanks in advance

[Alex]

Same question http://lemmasoft.renai.us/forums/viewto ... =8&t=25396

[jw2pfd]

I have seen this question pop up a few times and have had a similar interest in having more control over a menu so I started working on some code. I posted a basic version in the Cookbook section that may or may not be helpful -> http://lemmasoft.renai.us/forums/viewto ... 51&t=25460

[bg_nocturnal]

I already did something similar in another topic. I believe the same approach can help make this work, too:

Code: Select all

screen choice:

    window: 
        style "menu_window"        
        xalign 0.5
        yalign 0.5
        
        vbox:
            style "menu"
            spacing 2
            
            for caption, action, chosen in items:
                
                if action:  
                    
                    if " (disabled)" in caption:
                        $ caption = caption.replace(" (disabled)", "")
                        button:
                            action None
                            style "menu_choice_button"
                            
                            text caption style "menu_choice"
                    else:
                        button:
                            action action
                            style "menu_choice_button"

                            text caption style "menu_choice"
                    
                else:
                    text caption style "menu_caption"

Open your project's screens.rpy file and replace the part which starts with "screen choice" and ends right before "init -2 python" with the code above.

Then, when you want to show an unclickable option, just add " (disabled)" in its text like this:

Code: Select all

    menu:
        "Choice 1": # This is a normal choice
            # Stuff resulting from Choice 1
        "Choice 2 (disabled)": # This will be unclickable and appear as "Choice 2"
            pass # The contents of this block won't actually be used

[Taddy]

Hello guys.

I am sorry about the stupid question. Is this method is still work? Whatever I do, it doesn't work for me. I've tried many variations of this method, but the choice is still selecteble.
Maybe I make something wrong. Off course I can use

define config.menu_include_disabled = True

But I don't need it for all choises with variables.

I just change code in screen choice:

Code: Select all

screen choice:

    window:
        style "menu_window"
        xalign 0.5
        yalign 0.5

        vbox:
            style "menu"
            spacing 2

            for caption, action, chosen in items:

                if action:

                    if " (disabled)" in caption:
                        $ caption = caption.replace(" (disabled)", "")
                        button:
                            action None
                            style "menu_choice_button"

                            text caption style "menu_choice"
                    else:
                        button:
                            action action
                            style "menu_choice_button"

                            text caption style "menu_choice"

                else:
                    text caption style "menu_caption"

and add " (disabled)" in choises

Code: Select all

hm "It's evening, what would I do?"
    menu:
        "Watch TV - not available in the current version  (disabled)":
            pass
        "Go to bed early":
            hm "I'm so tired, I'd better go to bed."
            stop music fadeout 1.0
            scene i34 with dissolve
            pause
            return
 

But nothing heppen, choise still selecteble.

[Remix]

The current way of doing things is to use conditionals on the choices and set config.menu_include_disabled to True

Code: Select all

define config.menu_include_disabled = True

default allow_choice = False

label start:
    "It's evening, what would I do?"
    menu:
        "Watch TV - not available in the current version" if allow_choice:
            pass
        "Go to bed early":
            "I'm so tired, I'd better go to bed."
    return
 

[Taddy]

The current way of doing things is to use conditionals on the choices and set config.menu_include_disabled to True

Thanks to the66, I found the problem, why not work for me. I used his code.

Code: Select all

screen choice(items):
    style_prefix "choice"

    vbox:
        for i in items:
            $ disabled = i.kwargs.get("disabled", False)
            textbutton i.caption action i.action sensitive not disabled

menu:
    "Option 1":
        "bla"
    "Option 2" (disabled=True):
        "bla"

[SavedByZero]

The current way of doing things is to use conditionals on the choices and set config.menu_include_disabled to True

Code: Select all

define config.menu_include_disabled = True

default allow_choice = False

label start:
    "It's evening, what would I do?"
    menu:
        "Watch TV - not available in the current version" if allow_choice:
            pass
        "Go to bed early":
            "I'm so tired, I'd better go to bed."
    return
 

Can you please show an example of where and how to change the value of allow_choice for one option, then reset it for the others? I tried to do it after the first quote choice (where you currently have "if allow choice") but it's not working.

Also, how would we swap in a "disabled button" graphic for disabled choices?