NVL and ADV

[-Ren-]

Hello,

I was wondering if it is possible to show both adv and nvl dialogue windows on screen at the same time?
I am trying to implement a system similar to that of a cell-phone overlay, that will display a message conversation between two characters, but also with the ability to use adv as this is happening, without one being hidden to show the other.

Is this possible? If not, could you recommend another method of doing something like this? Programming isn't my strongest area and I'm really stumped on this!

Thanks.

[xavimat]

To add a cellphone or a message board better use your own screen and do not use nvl.
You can use a viewport to scroll things in the phone (http://www.renpy.org/doc/html/screens.html#viewport)

Take a look at the Basic Message System by Saguaro, maybe it can help: http://lemmasoft.renai.us/forums/viewto ... 51&t=19295 (or maybe is too much for your needs...)

[xavimat]

Is something like this that you are looking for:

Code: Select all

# TEST CELLPHONE
define e = Character('Eileen', color="#c8ffc8")

label start:
    $ msg = [  ]
    show screen cellphone(msg)
    e "You've created a new Ren'Py game."
    $ msg.append("{b}Message One{/b}\nThis is the text of the message one.")
    e "Once you add a story, pictures, and music, you can release it to the world!"
    $ msg.append("{b}Message Two{/b}\nThis is the amazing text of message two. And can be sooooo long....")
    e "Understood?"

    return

screen cellphone(messages):
    side "c b r":
        area (590, 10, 200, 200)
        viewport id "vp":
            draggable True
            mousewheel True
            vbox:
                text "{b}MESSAGES:{/b}"
                null height 10
                for message in messages:
                    text message
                    null height 10
        bar value XScrollValue("vp")
        vbar value YScrollValue("vp")

Put this code in the script.rpy of a new game (deleting the previous example text).

If you need more help, just ask.