Problem relating to input name[SOLVED]

[AsHLeX]

How do I put this... It's like after the character input his/her name, I want to ask them "What is your name?" again just for fun... But for some reason, even if I type the exact same thing, it still registers as "WRONG" (incorrect).

Xavimat's code:

Code: Select all

# Reply and Reply2
# by xavimat (cc-by, 2013)
# inspired by fiorica's "The Doll's Stories" and SusanTheCat's "Thera'Py"
# improved with help of jw2pfd

init python:

    def reply(question = "Yes or no?",
        answers = "yes,no",
        invalid_character = None,
        invalid_answer = "(Invalid answer)",
        show_answers = False):

        thequestion = question
        found_it = ""
        ans = answers.replace(" ", "")
        ans = ans.split(",")
                       
        if show_answers:
            thequestion += " {size=-10}("
       
            for element in ans:
                thequestion += element + ', '
            thequestion = thequestion[:-2] + "){/size}"           
       
        while found_it == "":
           
            phrase = renpy.input(thequestion)
            phrase = phrase.lower()       

            for chara in ',.;:!?-+*()[]{}&%$':
                phrase = phrase.replace(chara, ' ')           
            phras = phrase.split()
       
            for element in ans:
                for theword in phras:
                    if found_it == '' and element == theword:
                        found_it = element
                       
            if found_it == "":
                found_it = "WRONG"

        return found_it

Input name (1st time):

Code: Select all

label naming:
        $ player_name = renpy.input("What is my name?")
        $ player_name = player_name.strip()
        if player_name == "":
            jump naming
        else:
            play sound "pong.wav"
            hide you

How I used it:

Code: Select all

"Note: Input your name in the EXACT form that you entered in the beginning."
            $ r = reply("What is your name?", "[player_name]")
            if r == "[player_name]":
                $ Kyo += 1
                show kyo smile
                kyo "*laughs* Sorry, sorry. {w}I was just kidding with you."
            elif r == "WRONG":
                $ renpy.block_rollback()
                show kyo urgh
                kyo "... ..."

Like for example, if I keyed in my name as "AsHLeX" the first time, and the second time I did the same thing, for some reason Kyo still goes "... ...".
I don't know where I went wrong...
*Completely lost now*
Thank you so much for reading this/replying!

[philat]

I haven't bothered to look through the code very closely, but for what you're trying to accomplish, is there a point to using that code as opposed to just taking another input (say, player_name_2) and checking it against player_name?

[mjshi]

Basically what philat was saying, but here's a concrete example--

Code: Select all

init:
    $ playername = "Charlie"
    $ name_check = None


c = DynamicCharacter("playername")

label start:
  
    $ playername = renpy.input("Please input your name!", default="Charlie")
    
    "Hm, why don't you input your name again?"
    
    $ name_check = renpy.input("Again@")
    
    if playername == name_check:
        
        "So your name is [playername], right?"
        
    else:
        
        "Is your name [playername] or [name_check]?!?"

[AsHLeX]

Okay, got it. Thanks!!!!
You guys really saved me there ^^"

[xavimat]

I agree with philat ans mjshi. What you need is another input to check if they match.

On the other hand, here is the reason your initial code doesn't work:
First: You use the variable player_name inside "[]" when it's not needed, and I suspect there is some problem here. There are two lines that must be:

Code: Select all

$ r = reply("What is your name?", player_name)
if r == player_name:

Second: The reply() function offers more playability. It expects the user to enter some text (like "Why are you asking me again. I've said you already that my name is AsHLeX!")
But, to avoid problems with case, the function lowers the answer given by the user. It doesn't lower the "possible answers" because it expects the developer to put them in lowercase.
In your case, you don't want to change the "case", the you can delete the line:

Code: Select all

phrase = phrase.lower()

With this two changes, the code should work. But, as we've said, maybe is not what you need here.

[AsHLeX]

@xavimat:
Got it, thanks loads!