Change player's name with a fixed first letter

[Lockvia]

I have been thinking of using a story plot where the protagonist first letter in their name is the same as the rest of their family. Which made me wonder if it's possible to have an option of having a custom player's name but with a condition that the first letter needs to start with a specific letter like the letter 'M'.

[78909087]

To be honest, I became rather annoyed quickly with allowing people to choose their names. Now I set it as a menu, with prespecified names that people can choose. Here's a script example.

Under characters:

Code: Select all

define me = DynamicCharacter("povname", color=(192, 64, 64, 255))

In the script, where the person should choose their name:

Code: Select all

menu:

        nvlq "Your name..."
        "Alex.":

            $ povname = "Alex"
            nvl clear

        "Aaron.":

            $ povname = "Aaron"
            nvl clear

        "Jack.":

            $ povname = "Jack"
            nvl clear

        "Ben.":

            $ povname = "Ben"
            nvl clear

        "Iden.":

            $ povname = "Iden"
            nvl clear

Don't mind the nvl clear- I was using a menu in NVL mode, but this would work in normal mode too.


You can use this idea with names that start with 'M' and it shouldn't make much of a difference.

[PyTom]

Slightly more complex, you could redefine the input screen to be:

Code: Select all

screen input(prompt):

    window style "input_window":
        has vbox

        text prompt style "input_prompt"
        hbox:
            text "M"
            input id "input" style "input_text"

    use quick_menu

and then use:

Code: Select all

$ povname = "M" + renpy.input("I know my name begins with M, but what is it?").strip()

[xavimat]

You can try:

Code: Select all

label start:
    $ povname = ""
    while not povname.startswith("M"):
        $ povname = renpy.input("My name is...", default="M").strip()
        if not povname.startswith("M"):
            "Mmmmmm. I don't think so. My name starts with 'M'."