rock paper scissors on renpy [solved]

[ishify]

I have found this code while searching about how to implement the game in renpy.

I am currently having trouble with the rps_beats bit because I don't really know what to do after declaring it, or what to put in it.

Code: Select all

label rps:

    menu:
        "Rock!":
            $ rps_player = "rock"
        "Paper!":
            $ rps_player = "paper"
        "Scissors!":
            $ rps_player = "scissors"
            
    $ rps_npc = renpy.random.choice(["rock", "paper", "scissors"])

    e "I choose %(rps_npc)s!"

    if (rps_player, rps_npc) in rps_beats:

        e "You beat me!"

    elif (rps_npc, rps_player) in rps_beats:

        e "I win!"

    else:

        e "It's a tie! Let's do it again!"
        jump rps

    # ...

[philat]

Well, seems like it's just a matter of creating the list. Stick this anywhere before the if conditionals.

Code: Select all

$ rps_beats = [("rock", "scissors"), ("scissors", "paper"), ("paper", "rock")]

[PyTom]

Since it doesn't actually change, I'd suggest placing this in a define.

Code: Select all

define rps_beats = [("rock", "scissors"), ("scissors", "paper"), ("paper", "rock")]

Actually, it's probably more stylistic to name a constant like this RPS_BEATS - the all-uppercase lets us know it's a constant that we should never change, and never expect to change. This doesn't change the behavior at all, but it lets people reading your code - including yourself in a few days, months, or years - know more about the variable.

[ishify]

Oh, so that's how it works.

Ah, yes, the tip would come in handy. Thank you.