Coercing to Unicode: Error when including int as input

[DesertFox]

Playing around with some stats that the player can enter. Start by getting them to enter their current weight in order to work out their goal weight. RenPy seems to think goal_weight should return a string rather than an integer and I'm not certain how to change this. There are also some issues with the first if current_weight > 100 in that it will accept any number whether or not it's below 100. Does renpy.input convert what the player enters? Does it remain a string rather than acknowledge an integer?

Code: Select all

label enter_weight:    
    
    $ difference = 10
    $ current_weight = renpy.input("What is your current weight?", allow='0123456789', exclude='qwertyuiopasdfghjklzxcvbnm,./;', length=3)
    
    if current_weight > 100:
        "Okay, so your current weight is [current_weight]."
    elif current_weight < 100:
        "Please enter a correct number!"
        jump enter_weight
    else:
        "Please enter a correct number!"
        jump enter_weight
    
    "Do you want to gain weight or lose weight?"
    
    menu:
        "Gain weight":
            $ gain_weight = True
            $ goal_weight = current_weight + difference
        "Lose weight":
            $ gain_weight = False
            $ goal_weight = current_weight - difference
            
    e "So your current weight is [current_weight] and your goal weight is [goal_weight]."

Code: Select all

While running game code:
  File "game/script.rpy", line 38, in script
    $ goal_weight = current_weight + difference
  File "game/script.rpy", line 38, in <module>
    $ goal_weight = current_weight + difference
TypeError: coercing to Unicode: need string or buffer, int found

[xela]

Code: Select all

    $ difference = 10
    $ current_weight = renpy.input("What is your current weight?", allow='0123456789', exclude='qwertyuiopasdfghjklzxcvbnm,./;', length=3)
    $ current_weight = int(current_weight)

Try this.

[DesertFox]

That works great!

Just a quick ask - Will that goal_weight remain at its initial value or will it continue to change as current_weight changes? So if the player can continue to input their current_weight and change that value... Will I need to alter goal_weight to a persistent variable?

For instance, later on I have this, that either chastises the player for improving on their current_weight or congratulates them.

Code: Select all

if gain_weight:
        if current_weight < (goal_weight - 10):
            e "Oh dear, you've got a way to go still!"
        else:
            e "Hmm, not too bad! We can do this!"
    else:
        if current_weight > (goal_weight + 10):
            e "Oh dear, you've got a way to go still!"
        else:
            e "Hmm, not too bad! We can do this!"
        
    e "Cool!"

[philat]

goal_weight will remain static.

[DesertFox]

Awesome!

If I want to give the player the option to enter a decimal such as 180.5 rather than 180, do I use $ current_weight = float(current_weight) instead?

Code: Select all

$ current_weight = renpy.input("What is your current weight?", allow='0123456789', exclude='qwertyuiopasdfghjklzxcvbnm,./;', length=3)

[xela]

Sure thing.

[DesertFox]

Is there a certain expression to limit them to five characters to enter, but to ensure that after three characters, they have to enter a decimal point? So they can enter 180.0 but they can't enter 18000?

[xela]

Prolly not... but you can always analyze the input or create some form of a pattern.

[xavimat]

Just two notes:
- Using "allow" in renpy.input() is enough, there is no need to "exclude" (it's automatically excluded everything that is not "allowed")
- If you want decimals, you need to allow the "."

Code: Select all

renpy.input("What is your current weight?", allow='0123456789.', length=5)

[DesertFox]

@xavimat - Noted

@xela - Perhaps if there were two separate inputs for the int number and the decimal? So two boxes within a screen, next to one another. Then perhaps there's a way to append the int number with the decimal somehow...

[PyTom]

I'd just check for an exception when coercing the result to a float.

Code: Select all

label ask_weight:
    $ weight = input("How fat are you?")

    python:
        try:
            weight = float(weight) 
        except:
            renpy.jump("bad_weight")

    jump good_weight
    
label bad_weight:

     v "Let's try that again. Enter a number this time."
     jump ask_weight


label good_weight:
     if weight >= 300:
          v "Just my type."

...

[DesertFox]

Code: Select all

label good_weight:
     if weight >= 300:
          v "Just my type."

I think we've all just learned something about PyTom's type...

[PyTom]

I'm gonna call a foul there. Ren'Py is python based - we're not big on type checking.

(And I was assuming this was a character, not me. And.... enjoy your free code example.)

[DesertFox]

I'm gonna call a foul there. Ren'Py is python based - we're not big on type checking.

(And I was assuming this was a character, not me. And.... enjoy your free code example.)

Haha, just a joke

(And thank you!)