Make the screen have a constant sway/floating movement?

[Rainvillain]

Hello!

Working on a game that takes place aboard a ship and I was wondering if there was a way of having a subtle little swaying to the camera up and down to give the impression of being on water.

I know how to do basic stuff like panning the screen to the left/right/up/down but it's always been one-off things, that happen inbetween dialogue and not concurrently (or looping).
Not sure how to have a loopable "transform" animation that runs on the screen and characters in the background while the scene unfolds.
Any advice?

[Alera]

Hello!

I'm not sure how to apply it to the whole screen per se but you could easily apply such effect to individual elements (or all of them if you wish) using ATL

So it would be something like this:

Code: Select all

init-2:
    transform ship_sway:
        ypos -10 #You'll have to play around with these values and see what works for the images you've got and the effect you want.
        linear 0.5 ypos -15
        linear 0.5 ypos -10
        repeat #This is what makes it loop
                        
label start:
    show ship_bg at ship_sway

I hope this helps?

[PyTom]

You can apply it to the entire master layer with:

Code: Select all

show layer master at ship_sway

[Rainvillain]

Great, thank you both for the replies!!

[Rainvillain]

Follow up question: the "show layer master at ship_sway" works perfectly, but what if I wanted just one layer that didn't sway?
In my case, I want the ship (and characters) in the foreground to sway but not the sky and clouds, which are on their own layer behind everything else. Is there a way to basically apply sway to everything except for one layer?

[Kinsman]

You can add extra layers to your Ren'Py game by changing what's in config.layers.

Code: Select all

# Add a "backdrop" layer behind the master layer
init python:
    config.layers = [ 'backdrop', 'master', 'transient', 'screens', 'overlay' ]

# Later in your script..
show layer master at ship_sway

show cloudy_sky onlayer backdrop

[Rainvillain]

Ah, thank you Kinsman! That makes a lot of sense.

[Letitia_L]

I know this tread is a little old, but I wanted to thank Alera for her answer!

Code: Select all

init-2:
    transform ship_sway:
        ypos -10 #You'll have to play around with these values and see what works for the images you've got and the effect you want.
        linear 0.5 ypos -15
        linear 0.5 ypos -10
        repeat #This is what makes it loop
                        
label start:
    show ship_bg at ship_sway

I used this to make a running effect