I want to make a global timer.

[0xrgb]

Hello. I'm Korean renpy user, 0xrgb.

I want to make a global timer that records "play time".
It should start when renpy starts, end when renpy ends.
And It must not reset "play time" when renpy restarts. (So it should use persistent values)

I know how to make a simple timer(counter), using DynamicDisplayable or timer in screen.rpy.
So I was trying to make "play time" timer.
But I failed. My version of timer was so buggy, complicated and didn't work properly.

Is there a easy way to make "playtime" timer?

[PyTom]

Here's one way to do it, using config.periodic_callbacks to update a count stored in persistent.

Code: Select all

init python:
    import time

    # Create an object to store the last time playtime was updated.
    # Since we create it in init, it won't be saved or participate
    # in rollback.
    playtime = object()
    playtime.last_update = time.time()

    # Store the total playtime in persistent.total_playtime.
    if persistent.total_playtime is None:
        persistent.total_playtime = 0

    # This is called periodically (several times a second) to update
    # persistent.total_playtime.
    def playtime_callback():
        now = time.time()
        delta = now - playtime.last_update
        persistent.total_playtime += delta
        playtime.last_update = now

    config.periodic_callbacks.append(playtime_callback)

    def dynamic_playtime(st, at):
        return Text("{:.0f}".format(persistent.total_playtime)), 1.0

screen playtime:
    add DynamicDisplayable(dynamic_playtime)

label start:
    show screen playtime

    "..."

    return

[trooper6]

PyTom, I looked up config.periodic_callback in the documentation says:

config.periodic_callback = None
If not None, this should be a function. The function is called, with no arguments, at around 20hz.

What does "at around 20hz" mean?

[PyTom]

hz is Hertz, which is a standard unit meaning 1/s. So something that is called at 20hz is called 20 times per second.

[trooper6]

hz is Hertz, which is a standard unit meaning 1/s. So something that is called at 20hz is called 20 times per second.

I know of Hertz as unit of measurement...but my context for it has always been music rather than computer science (A = 440 and all that)...so I was having trouble figuring out how to translate arguments about where A should be to renpy functionality.

Thank you so much!