Is there any way to define button styles in choice menus?

[namastaii]

With a menu like:

menu:
"choice 1":
blah
"choice 2":
blah blah

Is there anyway to tell individual choices to be a specific button style? Like "choice 1" has a different button style than "choice 2" does? Is this even possible? And how would you do it? If not...is there any way to customize individual menus as a whole to go to certain button styles? I already have the button styles, I was just trying to do something specific and not sure how to do it.

[PyTom]

No, you basically have to use a screen to do this.

[namastaii]

Okay. I guess I could do an imagemap. Thanks^^

[Kinsman]

If you want to use a screen, you can get what you want with a little bit of Python code.

This code takes the regular choice screen and adds a few lines:

Code: Select all

screen choice(items):

    window:
        style "menu_window"
        xalign 0.5
        yalign 0.5

        vbox:
            style "menu"
            spacing 2

            for caption, action, chosen in items:
                
                python:
                    captionelements = caption.split("/")
                    if len(captionelements) > 1:
                        caption = captionelements[1]
                        menubuttonstyle = captionelements[0]
                    else:
                        menubuttonstyle = "menu_choice_button"

                if action:

                    button:
                        action action
                        #style "menu_choice_button"
                        style menubuttonstyle

                        text caption style "menu_choice"

                else:
                    text caption style "menu_caption"

When going through the menu items, it will break apart the text and look a forward slash(/). If it finds one, it takes what's to the left of the slash as a style name.

Code: Select all

init -2:
        
    style menu_choice_button_blue is menu_choice_button:
        background "#00f"
    style menu_choice_button_green is menu_choice_button:
        background "#0f0"

label start:

    e "Menu Test!"
    
    menu:
        "Here's a basic option":
            jump after_menu
        "menu_choice_button_blue/Here's a bluish option":
            jump after_menu
        "menu_choice_button_green/Here's a greenish option":
            jump after_menu

label after_menu:
    
    e "Good choice!"

    return

[namastaii]

Thanks I should try that out.