variables and classes

[bebeesun]

im back again and there's something that i need help with that is very simple. but i cant figure it out bc i just learned about classes today so im new to it. im trying to make a menu that displays a list of characters and how much they are in love with the main character....

Code: Select all

init python:
    

    class Lover():
        def __init__(self, name, points):
            self.name = name
            self.points = points 
            lovers.append(self)
        
     

            
screen lovers:
    modal True
    $ lovers= [name for name in lovers]
    frame:
        xpos 942
        ypos 650
        xsize 510
        ysize 405
        
        vbox:
            label "lovers"
            if name in lovers:
                 text name.name + #points go here....
                 textbutton "Close" action Hide("lovers")

i just want to be able to display the characters points next to the name thats all.

[Iylae]

Try the following:

Code: Select all

init python:
    
    lovers = []   #initialise the lovers variable as an array/list using []
    class Lover():
        def __init__(self, name, points):
            self.name = name
            self.points = points 
            lovers.append(self)
        
    Lover("Ariadne",0)   #create a lover
    Lover("Belle",0)     #create another lover

            
screen lovers():
    modal True
    frame:

        # I removed the pos vars because it wouldn't display on my resolution

        vbox:
            label "lovers"
            for lover in lovers:    # note the change here.
                text lover.name + ": " + str(lover.points)    # as lover.points is an integer, we use str() to turn it into a string
            textbutton "Close" action Hide("lovers")
                 
label start:
    show screen lovers  #  actually show the screen
    ""  # waits for the user to click before ending

[bebeesun]

thank you so much!!

[bebeesun]

wait i have another question...they dont show up on the list at the same time. only one does.

[xela]

wait i have another question...they dont show up on the list at the same time. only one does.

They should both show up, but that is a bad code that will fail you in a real gameplay on saving, try:

Code: Select all

init:
   
    default lovers = []

    python:
        class Lover(object):
            def __init__(self, name, points):
                self.name = name
                self.points = points
                lovers.append(self)
       

screen lovers():

    modal True

    frame:
        has vbox
        label "lovers"
        for lover in lovers:    # note the change here.
            text lover.name + ": " + str(lover.points)    # as lover.points is an integer, we use str() to turn it into a string
        textbutton "Close" action Hide("lovers")
                 

label start:
    $ Lover("Ariadne", 0) # create a lover
    $ Lover("Belle", 0) # create another lover

    show screen lovers # actually show the screen

    pause # waits for the user to click before ending

That prolly won't fix whatever might be causing the issue with the other actor not showing but it will save properly.

[bebeesun]

thankk you!! your code actually fixed the problem. that also happened to me last time i tried making a menu idk what im doing to make that happen but thank you!!

[Iylae]

Honestly I need to post-it note the default keyword to my monitor. Thanks for picking up on that xela.

... Also instantiating variables in start: and not in init:

[xela]

Honestly I need to post-it note the default keyword to my monitor. Thanks for picking up on that xela.

NP.

+ You shouldn't instantiate classes in the init, you may run into a similar issue with saving/loading.