How to do Comparisons Between Variables?

[EusthEnoptEron]

You could use the .reverse() method of the List object after you've sorted it, I guess.

[PyTom]

You want to do:

jump expression scores[-1][1]

The -1 refers to the last item in the scores list. Sorry about forgetting this in my original post... about 90% of the time when I sort, I want the smallest rather than the largest number.

[cloverfirefly]

Thanks, PyTom. Problem solved.

For anyone following along, here is the fixed version of the sample game I posted earlier.

Code: Select all

label start:
    
    $ mary_score = 2
    $ eileen_score = 1
    $ lucy_score = 3
    
    "Eileen's score is %(eileen_score)s."
    "Lucy's score is %(lucy_score)s."
    "Mary's score is %(mary_score)s."
    
    python:
        scores = [
            (eileen_score, "eileen_ending"),
            (lucy_score, "lucy_ending"),
            (mary_score, "mary_ending"),
            ]

        scores.sort()

    jump expression scores[-1][1]
    
label eileen_ending:
    "Eileen likes you the most!"
    return
    
label lucy_ending:
    "Lucy likes you the most!"
    return
    
label mary_ending:
    "Mary likes you the most!"
    return

[Watercolorheart]

What does this part do
scores = [
(eileen_score, "eileen_ending"),
(lucy_score, "lucy_ending"),
(mary_score, "mary_ending"),
]

Is it connecting the name of the variable to the jump?

[PyTom]

It's actually connecting the value of the variable to the jump. Basically, what we do is:

1) Create a list of score-label pairs.
2) Sort that list.
3) Jump to the label of the last thing in the list, which is the one with the highest score.

Being able to do this sort of thing is why it's important to include a full-fledged programming language as part of your visual novel engine. While you could do this for a few labels with simple compare-jumps, that can become unwieldy fast, while this approach scales easily.

[Gau_Veldt]

What does this part do
scores = [
(eileen_score, "eileen_ending"),
(lucy_score, "lucy_ending"),
(mary_score, "mary_ending"),
]

Is it connecting the name of the variable to the jump?

This list uses tuples to connect the scores to the ending to call if that score wins. The winning score is determined by sorting the list which orders it by score, with the highest score being at the end of the list. A list like this works well when there are a lot of characters.