Disable an option after it's chosen a set amount of times

[User144]

How do I make it so you can pick a choice from a menu in Renpy a set amount of times before it becomes unavailable for the day?

For example

label example:
menu:
"Choice 1":
"blah blah blah"
jump example
"Choice 2":
"something something"
jump example
"Choice 3":
"This and that"
"etc"
jump example

While I want to be able to pick more than one or the same one several times I don't want it to be an infinite amount of times.

[IrinaLazareva]

Code: Select all

init:
    $ sdf = 0
    $ adf = False   
    
label start:
    ##...
    
 

label example:
    if sdf == 5:
        jump nexto
    menu:
        "Choice 1":
            "blah blah blah"
            $ sdf += 1
            jump example
        "Choice 2":
            "something something"
            $ sdf += 1
            jump example
        "Choice 3":
            "This and that"
            $ sdf += 1
            jump example
        "Bonus (Only ONE try)" if adf == False:
            "..."
            $ sdf += 1
            $ adf = True
            jump example            
            
label nexto:
    "ОК"        

[xavimat]

Code: Select all

label new_day:
    
    ## Assuming there are three choices
    $ choi = [0, 0, 0]
    $ times = 3
    
label example:
    
    menu:
        "Choice 1" if choi[0] < times:
            $ choi[0] += 1
            "Bla bla"
        "Choice 2" if choi[1] < times:
            $ choi[1] += 1
            "Bla bla"
        "Choice 3" if choi[2] < times:
            $ choi[2] += 1
            "Bla bla"
        "Another Option":
            "You need an option that will always be visible."
            "Otherwise the menu could be empty and the game blocked."                
            
    jump go_on