Temporary third text window

[fundogmo]

My brain has melted trying to theorize an answer on my own, but I've been making no progress and need help!

I would like to see if there's a way to have a third text window pop up at the top of the screen during certain lines, then slowly fade away during the next line, similar to Steins;gate (which I know isn't a renpy game).

I made a mockup of what I imagined it would look like it.



Is there a relatively easy way to code this in using just a few lines? Or is it a little more complicated for a bunch of throwaway jokes?

Thank you in advance!

[namastaii]

I don't know if it'll be much help but someone asked something similar viewtopic.php?f=8&t=15002
I'd look at the replies and links inside that and see if there's anything that can help. It could have changed but this post was in 2012 and it was stated that ren'py wasn't able to do this so you had to basically rig your own thing with a screen instead.

[trooper6]

I think the easiest thing would be to use renpy.notify, but also create a custom notify screen that looks as you want it to look.

Here is an example of a notify screen I made (and put in my screens.rpy):

Code: Select all

##############################################################################
# Notify Screen
#
# This is overriding the Notify screen from renpy/common/00action_other.rpy
transform _notify_transform:
    # These control the position.
    xalign 0.5 yalign 0.6

    # These control the actions on show and hide.
    on show:
        alpha 0
        ease .25 alpha 1.0
        ease .7 ypos 0.4 
    on hide:
        linear .5 alpha 0.0

screen notify:
    zorder 100
    style_group "notify"

    text message at _notify_transform

    # This controls how long it takes between when the screen is
    # first shown, and when it begins hiding.
    timer 2.0 action Hide('notify')

init -2:
    style notify_text:
        size 28
        color "#f00"
        outlines [(1, "#ffffff", 0, 0)]

And using notify is as easy as:

$renpy.notify("*Translator's Note...")

Notify is documented here:
https://www.renpy.org/doc/html/screen_a ... tml#Notify

The Notify screen is documented here:
https://www.renpy.org/doc/html/screen_s ... tml#notify

And just make your screen using screen language:
https://www.renpy.org/doc/html/screens.html

[fundogmo]

Thank for the links, namastaii. I was browsing through them, and it seems like a possible avenue.

The notify function however, seems like the quick fix that will work perfectly. Thank you very much trooper6! I can't wait to experiment implementing it!