Resizing a frame

[Lezalith]

Sorry for asking this, I just can't seem to understand how Frames work. Atleast I think I need Frame for this.
I want to resize skillcheck.png (Which is just a blue box at the moment) to be covering the entire text in vbox.
As I will have multiple versions of the text, I don't want to make a different box for each of them.

Code: Select all

screen skillcheck:
    frame:
        background "skillcheck.png"
        left_padding 10
        right_padding 10
        yminimum 55
        xminimum 232
        at skillcheckTransform
        vbox:
            text "This is => Some sort of text"

This is what I came up with, but the image stays the same.

[morg]

go to options.rpy and type

Code: Select all

style.frame.background = Frame("skillcheck.png", 10, 10)

Frame resizes the image to fit everything inside, the 10s are margins I believe.

[chocoberrie]

morg is correct!

From Aleema's textbox customization tutorial:

Dialogue boxes that use Frame look for the corners of the image, and then stretch whatever's in between to fit the proportions you give it in the code.



The numbers are the width and height of each corner of the box, in pixels.

[Lezalith]

Sorry, but that doesn't work. It changes the box with all the buttons in Main Menu (As I am still using the very default, not changed menu) and the "Are you sure you want to quit" thing, but it doesn't do anything to that vbox that I need.

It should work though, right? I mean,

From Aleema's textbox customization tutorial:

I was reading through this, doesn't seem like I took much from it.

[chocoberrie]

Ah, okay. Well, I did find this page in the documentation about vbox, maybe something there will help you?

Here are the box style properties that vbox can have, but I don't see Frame anywhere in the list. It seems to me that you might need to make your box image the size that you want the vbox to be... Frame is supposed to automatically resize the box, but from what I gather, it applies to the ADV dialogue box, and not to vbox...

The position style properties for vbox include these:

xsize - int
Equivalent to setting xminimum and xmaximum to the same value. This has the effect of setting the width of the displayable.

ysize - int
Equivalent to setting yminimum and ymaximum to the same value. This has the effect of setting the height of the displayable.

(This may be what you want, since the documentation says that xminimum and yminimum only work with displayables that can vary in size.)

I've never messed with vbox coding before, but I hope this helps in some way. ^^;;

[Lezalith]

I need the frame to be there, as vbox doesn't have any "background" option. The xsize and ysize does change the vbox height and widht (change the space the text is in), but doesn't do anything to the image itself.

I can't even change the size of the image with frame, when I use xsize and ysize.

Gash, I really wanna avoid having to do 96 versions of the same picture. Anyway chocoberrie, thank you for the effort.

[Lezalith]

I could avoid having to do 96 versions of the same picture, if only I could resize it with frame.
Not to automatically fit the text in vbox, just resize it.
Then I'd only have to do 96 versions of the frame parameters about which size it should be.

It still sucks, but it would beat the hours of editing the pictures...

[chocoberrie]

Hmmm... Here is the documentation for Frame. It points out that Frame also takes these common properties, which includes style.

style
The name of the style applied to this displayable. This may be a string name, or a style object. The style gives default values for style properties.

So based on this, I would think that

Code: Select all

style.frame.background = Frame("skillcheck.png", 10, 10)

would still work, you would just have to define your own style for this particular Frame box (e.g. style "skillcheck"):

Code: Select all

screen skillcheck:
    frame:
        style "skillcheck"
        left_padding 10
        right_padding 10
        yminimum 55
        xminimum 232
        at skillcheckTransform
        vbox:
            text "This is => Some sort of text"

And then you can define that style in options.rpy. Here is the documentation on styles.

I have no idea how you could define a style that lets you use Frame to resize skillcheck.png. This is just my wild guess:

Code: Select all

style skillcheck:
    background = Frame("skillcheck.png", 10, 10)

[Lezalith]

YES! I've reached the Promised Land!

Code: Select all

transform skillcheckTransform:
    xalign 0.5 yalign 0.5 alpha 1.0
    linear 1.5 yalign 0.0 alpha 0.0
    
style skillcheckStyle:
    background Frame("skillcheck.png", 10, 10)
    
screen skillcheck:
    frame:
        style "skillcheckStyle"
        at skillcheckTransform
        vbox:
            text "This is => Some sort of text"

Works perfectly. Now to work out the padding, borders... You saved me tons of time (Also made my work look more professional). I couldn't be more grateful, chocoberrie! <3

[chocoberrie]

Holy bananas!! That actually worked? Woohoo!! ;v; You're super welcome! <3

[xavimat]

The styles are useful when you need different frames to have the same properties.
If you have only that frame with that background you could put directly the property in the screen.

Code: Select all

screen skillcheck:
    frame:
        background Frame("skillcheck.png", 10, 10)
        at skillcheckTransform
        vbox:
            text "This is => Some sort of text"

(Defining the transform, obviously)

I think this way is easier to read and mantain in the future.