How to hide the navigation quick menu for a cutscene?

[Mooneon]

I want to temporarily hide the navigation quick menu so in my game it would look like a cutscene. How do you do this?

[PyTom]

You basically need to make it conditional in the screens that use it.

First off, default a quick_menu variable so it has the condition.

Code: Select all

default show_quick_menu = True

Then you need to modify the quick menu.

Code: Select all

screen quick_menu():
    if quick_menu:
        # Add an in-game quick menu.
        hbox:
            style_group "quick"

            xalign 1.0
            yalign 1.0

            textbutton _("Back") action Rollback()
            textbutton _("Save") action ShowMenu('save')
            textbutton _("Q.Save") action QuickSave()
            textbutton _("Q.Load") action QuickLoad()
            textbutton _("Skip") action Skip()
            textbutton _("F.Skip") action Skip(fast=True, confirm=True)
            textbutton _("Auto") action Preference("auto-forward", "toggle")
            textbutton _("Prefs") action ShowMenu('preferences')

Then you can control the show_quick_menu variable to determin if it's shown.

Code: Select all

"Shown"
$ show_quick_menu = False
"Hidden"
$ show_quick_menu = True
"Shown"

[Katy133]

Just wanted to correct a small typo, since I'm using this as well:

Code: Select all

screen quick_menu():
    #edit under this line:
    if show_quick_menu:
        # Add an in-game quick menu.
        hbox:
            style_group "quick"

            xalign 1.0
            yalign 1.0

            textbutton _("Back") action Rollback()
            textbutton _("Save") action ShowMenu('save')
            textbutton _("Q.Save") action QuickSave()
            textbutton _("Q.Load") action QuickLoad()
            textbutton _("Skip") action Skip()
            textbutton _("F.Skip") action Skip(fast=True, confirm=True)
            textbutton _("Auto") action Preference("auto-forward", "toggle")
            textbutton _("Prefs") action ShowMenu('preferences')

[Minuteman]

Hello
What if I use '$ quick_menu = False' to hide quick menu? Is this is alright?

[Imperf3kt]

If you are using a recent version of Ren'Py, yes, that is fine. The quick_menu variable is already defined within screens.rpy