Making quick menu appear only during dialogue screens?[FIX]

[Sleepy]

I've been playing around with the newest update and while I've been able to convert most of my old build into the new update, I've been having some problems with the quick menu.

In the old version, the quick menu automatically appeared or hid depending on if you were in the middle of a dialogue scene and then would disappear during other screens (such as, exploration screens). However, I'm finding that the quick menu will keep showing even during exploration screens.

I know "config.overlay_screens.append("quick_menu")" is what helps it appear but if I move it or blank it out, the quick menu will disappear entirely. Likewise, I haven't been able to get something like this to work:

Code: Select all

    if say:
        hbox:
            style_prefix "quick"

            xalign 0.75
            yalign 0.98

            textbutton _("Back") action Rollback()
            textbutton _("History") action ShowMenu('history')
            textbutton _("Skip") action Skip() alternate Skip(fast=True, confirm=True)
            textbutton _("Auto") action Preference("auto-forward", "toggle")
            textbutton _("Save") action ShowMenu('save')
            textbutton _("Q.Save") action QuickSave()
            textbutton _("Q.Load") action QuickLoad()
            textbutton _("Prefs") action ShowMenu('preferences')

Are there any particular ways to get around this?

[juliaa]

I wonder if this is the problem

Code: Select all

# Ensure this appears on top of other screens.
    zorder 100

It seems like it places the menu on top of all screens. Maybe you have to specify which screens you want it on instead.

This is just my thinking because am a noob to ren'py lol.

[Sleepy]

I don't think that's the issue. I've blanked that line out before but the quick menu screen will continue to show on all screens, including the choice menu or during transitions.

IIRC, what Zorder does is overlay quick menu over another screen (i.e: the say screen). Which I want, just not where it's supposed to.

EDIT:

I looked over the coding for the older version of Ren'py and found a fix. In the older version, the say screen includes "use quick_menu". So I removed "config.overlay_screens.append("quick_menu")" from the quick menu screen and added "use quick_menu" to the say screen:

Code: Select all

screen say(who, what):
    style_prefix "say"

    window:
        id "window"

        text what id "what"

        if who is not None:

            window:
                style "namebox"
                text who id "who"

    # If there's a side image, display it above the text. Do not display
    # on the phone variant - there's no room.
    if not renpy.variant("small"):
        add SideImage() xalign 0.0 yalign 1.0
    
    # Use the quick menu.
    use quick_menu

[juliaa]

Ok I see I was no help lol, but am glad you got it sorted.

[XxrenxX]

Just thought I would add (I'm aware this is old) but if you are using any screens where you have to window hide, you will have to hide screen quick_menu as well.

Code: Select all

label cell: 
    window hide
    hide screen quick_menu
    show cell at pickup
    $ renpy.pause(0.2)
    return

quick example in case I didn't fully make sense.