Imagebutton appears before animation

[kl7]

Hi, everyone! Need help with imagebuttons.

I have two imagebuttons in one screen and I want my second button to appear with delay 1sec, with scaling from 0 to 0.5 and with alpha from 0 to 1.

The problem is that - the second imagebutton (which is with delay) appears before animation starts, and it's clickable.

I know that i can create two screens for each button and add pause between them, but the question - is it possible with one screen?

Sorry for my english)

My code:

Code: Select all

transform anim_01:
    parallel:
        zoom 0.0
        linear 0.25 zoom 0.6
    parallel:
        zoom 0.6
        linear 0.1 zoom 0.5

transform anim_02:
    pause 1
    parallel:
        zoom 0.0
        linear 0.25 zoom 0.6
    parallel:
        zoom 0.6
        linear 0.1 zoom 0.5


screen my_buttons:
    
    imagebutton xanchor 1.0 yanchor 1.0 xpos 300 ypos 200 at anim_01:
        focus_mask True
        idle "images/button01_idle.png"
        hover "images/button01_hover.png"
        action Jump("label01")
   
    imagebutton xanchor 1.0 yanchor 1.0 xpos 300 ypos 200 at anim_02:
        focus_mask True
        idle "images/button02_idle.png"
        hover "images/button02_hover.png"
        action Jump("label02")

[Ocelot]

Set zoom and alpha to 0 before pause:

Code: Select all

transform anim_02:
    zoom 0.0
    alpha 0.0
    pause 1
    parallel:
        linear 0.25 zoom 0.5
    parallel:
        linear 0.1 alpha 1.0

[kl7]

Ocelot,

it helps to hide this imagebutton, but it is still clickable before animation starts.

UPD
i send the code where positions of the buttons are same, which is mistake. In my original code positions of buttons are different, so the problem is not solved.

[jw2pfd]

It's possible to prevent the user from clicking it for a set amount of time. I would try it this way although there may be an easier way. In your main code, you can add a variable just before you call the screen.

Code: Select all

    $ loaded = False

    # whatever code you have for your call screen

Then you can add a timer on your screen as well as change the buttons actions like this:

Code: Select all

screen my_buttons:
   
    imagebutton xanchor 1.0 yanchor 1.0 xpos 300 ypos 200 at anim_01:
        focus_mask True
        idle "images/button01_idle.png"
        hover "images/button01_hover.png"
        action If(loaded, "label01")    #<--- change the action here
   
    imagebutton xanchor 1.0 yanchor 1.0 xpos 300 ypos 200 at anim_02:
        focus_mask True
        idle "images/button02_idle.png"
        hover "images/button02_hover.png"
        action If(loaded, "label02")     #<--- change the action here

    timer 1.6 action SetVariable("loaded", True)  #you can change the 1.6 to whatever time value you need to fit the duration of the animation

[kl7]

jw2pfd,

It works perfect. Thank you!