Showing a new Menu once a goal is reached

[Dreamulex]

for my game, once you talk to three people I want a new menu will show up. This will be determined by points. I'm not sure about what I did wrong. If there's more than one way to do this then that would be more than appreciated.

Code: Select all

I'm sorry, but an uncaught exception occurred.

While running game code:
  File "renpy/common/00start.rpy", line 107, in script
    return
Exception: Could not find return label (u'/Users/Brixujel/Desktop/Visual Novals/Stranded/game/script.rpy', 1492537627, 33).

Code: Select all

label selection:
    
        if leave >= 3:
            menu:
            
                "Nadsarx":
                     jump food_Suppies
                         
                "Luna":   
                     jump machine_check
                        
                "Makiri (In development)":
                     jump plan_out_route
            
        if leave >= 3:
            menu:             
                "Leave the Island (In development)":
                     jump leave 

[Imperf3kt]

Why do you have two ifs for the same thing?

[Dreamulex]

There is one for when they have the first option then there is another for when they have all the options

[jw2pfd]

I think he is trying to point out that they're the same conditional:

Code: Select all

        if leave >= 3:

This means they're checking for exact the same condition instead of different ones. This isn't causing any sort of syntax error though. When does the error occur while the program is running? Is it right when the menu is supposed to display or at a different time?

[Saltome]

How about this?

Code: Select all

default talkedto = []
label start:
    if len(talkedto) == 3:
        "Talked to everyone."
        return
    menu:
        "People to talk to:"
        "Nadsarx":
            $ if "Nadsarx" not in talkedto : talkedto += ["Nadsarx"]
            "Talked to Nadsarx."
            #jump food_Suppies
                         
        "Luna":
            $ if "Luna" not in talkedto : talkedto += ["Luna"]
            "Talked to Luna."
            #jump machine_check
               
        "Makiri (In development)":
            $ if "Makiri" not in talkedto : talkedto += ["Makiri"]
            "Talked to Makiri."
            #jump plan_out_route
    jump start
    return

[Ocelot]

There is no need to emulate something RenPy already does:

Code: Select all

default talkedto = []
label start:
    menu:
        set talkedto
        "People to talk to:"
        "Nadsarx":
            "Talked to Nadsarx."
            #jump food_Suppies
                         
        "Luna":
            $ if "Luna" not in talkedto : talkedto += ["Luna"]
            "Talked to Luna."
            #jump machine_check
               
        "Makiri (In development)":
            "Talked to Makiri."
            #jump plan_out_route
        
        "Leave the Island (In development)" if len(talkedto) >= 3:
            'Left the island'
            return
    jump start

[Saltome]

Wait, what the heck is set?
I don't believe I have ever seen it before.
Is it mentioned anywhere in the docimentation?

Also you forgot to remove the one line.

Code: Select all

default talkedto = []
label start:
    menu:
        set talkedto
        "People to talk to:"
        "Nadsarx":
            "Talked to Nadsarx."
            #jump food_Suppies
                         
        "Luna":
            "Talked to Luna."
            #jump machine_check
               
        "Makiri (In development)":
            "Talked to Makiri."
            #jump plan_out_route
        
        "Leave the Island (In development)" if len(talkedto) >= 3:
            'Left the island'
            return
    jump start