Live Composite with optional stuff [Solved]

[sunwave]

So I was trying to switch from static sprites to a livecomposite setup because my artist went out of their way to not just deliver me some nice characters, but also the PSD files with several interchangeable poses. SO... now I feel compelled to use them (which would obviously give me lots of options in-game). This specific character consists of:
- A base (bottom layer)
- A head with expression (middle layer)
- An arm pose (on top)
- A blush (optional layer)

Now I have set up the code like this:

Code: Select all

#########################################################################
## SERENA

define S = Character('Serena', color="#FF6600", who_suffix = ':', what_prefix='"', what_suffix='"')
define S_who = Character('???', color="#FF6600", who_suffix = ':', what_prefix='"', what_suffix='"')

default s_head = "neutral"
default s_blush = None
default s_arms = "neither"

image serena = LiveComposite(
    (1719, 5448),
    (0, 0), "images/characters/serena/base/base.png",
    (0, 0), "images/characters/serena/head/[s_head].png",
#   (0, 0), "images/characters/serena/blush/[s_blush].png",
    (0, 0), "images/characters/serena/arms/[s_arms].png"
)

#########################################################################
### Technical game start

label start:

    stop music
    scene black
    window auto
    
#########################################################################
### Game start

    scene bg hallway1
    "This is the start of the test."

    show serena
    S "This is me! Pose me however you want!"
    $ s_head, s_arms = "annoyed", "both"
    S "Just... no weird things!"
    S "Get it?"
#   $ s_blush = "blush1"
#   S "Hey!"

    return

Sooo.... it works nice (ignoring the fact that the image is still its original size, haha).
But if I try to add the blush, it will complain that it can't find the blush file (obviously, because it's searching for a file with an empty name). Is there a way to add the blush to the composite image ONLY if the blush variable has a value? It probably could work with a conditionswitch but I can't seem to get it to work. I don't want to put an empty file in the "blush/noblush.jpg" because I simply don't want an empty file if there is a better way.

[Scribbles]

Probably not the best method - but what I used - I created a image with 1% opacity and used that as the "non" blush image to switch between

someone has to have a better way of doing that though lol

[Imperf3kt]

Can't you just make two live composite images?
One with the blush file, one without.

Then when you show the image, add a conditional there.

Knowing how you plan to use the blush would be helpful. Is it set from the main menu, or does the character blush under certain responses?

[sunwave]

Oh, you mean making one conditionswitch for the blush (or not), and if s_blush has a value, use one of the composites (with blush) and if it has no value use the other composite (without blush)? That would perhaps be possible. I was messing with the conditonswitch INSIDE the composite but I didn't consider the other way around. I'll try that now. I'll let you know if it worked or not. (And yeah, I just want to be able to change a variable on-the-fly to turn off/on the blush on her character model).

@Scribbles: Yeah, right now I have a 1x1 pixel image with an empty layer in it saved as "noblush". So basically the same thing. Haha.

[trooper6]

What you want is to use a ConditionSwitch in your LiveComposite.
ConditionSwitch is documented here: https://www.renpy.org/doc/html/displaya ... tionSwitch

Your code would look like something like this:

Code: Select all

default s_head = "neutral"
default s_blush = False
default s_arms = "neither"

image serena = LiveComposite(
    (1719, 5448),
    (0, 0), "images/characters/serena/base/base.png",
    (0, 0), "images/characters/serena/head/[s_head].png",
    (0, 0), ConditionSwitch(
        "s_blush == False", Null(),
        "True", "images/characters/serena/blush/blush1.png"),
    (0, 0), "images/characters/serena/arms/[s_arms].png"
)

[sunwave]

Awesome. Works like a charm. =)