Too much Variables?

[TraceOmega]

Hey there,
Im currently working on my first RenPy game and have a big issue to solve.

I nearly completed a minecraft-ish crafting system but at the final point, the one where the items come in, kills it.
Imagine a square with 9 sockets. Every socket has its own variable. If i go and say, for example, you put in the middle top and the middle middle socket a piece of metal and in the bottom middle a piece of wood, i can create a sword:

Code: Select all

                        if A2 == 2:
                            if B2 == 2:
                                if C2 == 1:
                                    m "Wundervoll! Ein einfaches Stahlschwert."
                                    jump forging_system_return
                                else:
                                    jump wrong_forging
                            else:
                                jump wrong_forging
                        else:

                            label wrong_forging:

                                m "Hmm, Ich glaube das wird nichts."

                                jump forging_system_return

But as the objects get bigger i stops working:

Code: Select all

                        elif A1 == 2:
                            if A3 == 2:
                                if B1 == 2:
                                    if B2 == 2:
                                        if B3 == 2:
                                            if C1 == 2:
                                                if C2 == 2:
                                                    if C3 == 2:
                                                        m "Exellent! Ein Vollstahlbrustharnisch."
                                                        jump forging_system_return
                                                    else:
                                                        jump wrong_forging
                                                else:
                                                    jump wrong_forging
                                            else:
                                                jump wrong_forging
                                        else:
                                            jump wrong_forging
                                    else:
                                        jump wrong_forging
                                else:
                                    jump wrong_forging
                            else:
                                jump wrong_forging

Even other methods not seem to work:

Code: Select all

                        elif A1 == 2 and A2 == 0 and A3 == 2:
                            if B1 == 2 and B2 == 2 and B3 == 2:
                                if C1 == 2 and C2 == 2 and C3 == 2:
                                    m "juhu"
                                    jump forging_system_return
                                else:
                                    jump wrong_forging
                            else:
                                jump wrong_forging
                        else:

                            label wrong_forging:

                                m "Hmm, Ich glaube das wird nichts."

                                jump forging_system_return

Is something wrong about it? Or is the multiple usage of variables in this case limited?
I also tried to put them all together in a single if clause, didnt work either.

Can someone help me with it?

If you want to help please use RenPy without init python, im still a newbie and dont understand anything with this python things.

[trooper6]

You can certainly combine variables...and you should.
You didn't post complete code, so I don't know if there are any indentation problems with your code.
You probably want to call to wrong_forging and return rather than using jumps.
Lastly, have your labels be fully outdented. They are their own blocks and shouldn't be inside any other block. That is why you are jumping or calling to them.

Code: Select all

default A2 = 2
default B2 = 2
default C2 = 1


label start:
    "Your game starts here"
    if A2 == 2 and B2 == 2 and C2 == 1:
        "Wundervoll! Ein einfaches Stahlschwert."
    else:
        call wrong_forging
        
    "Forging done."
    
    return
    
label wrong_forging:
    "Hmm, Ich glaube das wird nichts."
    return

[Ocelot]

I am interested in what do you have before elif statement in your code.

Remember: elif block is considered only if corresponding if statement evaluated to false. Consider:

Code: Select all

if cond1:
    if cond2:
         '1 and 2'
    else:
        'only 1'
elif cond3:
    if cond4:
        '3 and 4'
    else:
        'only 3'
else:
    'nothing'

In case when cond2 is false and all other are true, you will get 'only 2' displayed, even if you expect anything else (like '3 and 4'): cond1 is true, so all alternative paths are not considered at all.

[TraceOmega]

First, thank you guys for helping.

@ trooper6:

I see what you want to tell me, but the part of code you prepared, is still working in my code.
The acual problem is, that, as the needed variables exceeds a number of 3 for one "recipe", it doesnt operate with them anymore.
Even if the variables are set up perfectly, i dont get the result i should.
Anything without any error, just not working probably.

@Ocelot:

The 3 codeparts are right after another.
These are "recipes".
They just define what you are able to create.
- or they should do.

[trooper6]

Put this code in a fresh project, and you'll see that it works:

Code: Select all

default A1 = 2
default A3 = 2
default B1 = 2
default B2 = 2
default B3 = 2
default C1 = 2
default C2 = 2
default C3 = 2


label start:
    "Your game starts here"
    if A1 == 2 and A3 == 2 and B1 == 2 and B2 == 2 and B3 == 2 and C1 == 2 and C2 == 2 and C3 == 2:
        "Exellent! Ein Vollstahlbrustharnisch."
    else:
        call wrong_forging
        
    "Forging done."
    
    return
    
label wrong_forging:
    "Hmm, Ich glaube das wird nichts."
    return

So I think there is something else wrong in your code. But you didn't post the full code so we can't really tell what it is. As ocelot notes, you are giving us bits without them being connected. Paste the entire code in one chunk so we can see if there is some weirdness.

Also, I think there is some better way of doing this than what you are doing...though it probably would involve Python.

[TraceOmega]

I cant copy/paste the whole game for reasons but i think this is the relevant part.
There you go:

Code: Select all

              
              label forging_system:

                    $ A1 = 0
                    $ A2 = 0
                    $ A3 = 0

                    $ A1_wood = 0
                    $ A2_wood = 0
                    $ A3_wood = 0

                    $ A1_steel = 0
                    $ A2_steel = 0
                    $ A3_steel = 0

                    $ B1 = 0
                    $ B2 = 0
                    $ B3 = 0

                    $ B1_wood = 0
                    $ B2_wood = 0
                    $ B3_wood = 0

                    $ B1_steel = 0
                    $ B2_steel = 0
                    $ B3_steel = 0

                    $ C1 = 0
                    $ C2 = 0
                    $ C3 = 0

                    $ C1_wood = 0
                    $ C2_wood = 0
                    $ C3_wood = 0

                    $ C1_steel = 0
                    $ C2_steel = 0
                    $ C3_steel = 0


                    label forging_system_return:

                        call screen image_forging_system

                        $ result = _return

              #------------------------------------Imagecheck----------------------------------------------------------------

              #--------------------------------------------------------------------------------------------------------------
                        if result == "A1":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ A1 = 1

                                    $ A1_wood = 1

                                    #---------------ReturnV---------

                                    $ A1_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ A1 = 2

                                    $ A1_steel = 1

                                    #---------------ReturnV---------

                                    $ A1_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ A1 = 0

                                    $ A1_steel = 0

                                    $ A1_wood = 0

                                    jump forging_system_return

                        if result == "A2":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ A2 = 1

                                    $ A2_wood = 1

                                    #---------------ReturnV---------

                                    $ A2_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ A2 = 2

                                    $ A2_steel = 1

                                    #---------------ReturnV---------

                                    $ A2_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ A2 = 0

                                    $ A2_steel = 0

                                    $ A2_wood = 0

                                    jump forging_system_return





                        if result == "A3":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ A3 = 1

                                    $ A3_wood = 1

                                    #---------------ReturnV---------

                                    $ A3_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ A3 = 2

                                    $ A3_steel = 1

                                    #---------------ReturnV---------

                                    $ A3_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ A3 = 0

                                    $ A3_steel = 0

                                    $ A3_wood = 0

                                    jump forging_system_return



                        if result == "B1":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ B1 = 1

                                    $ B1_wood = 1

                                    #---------------ReturnV---------

                                    $ B1_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ B1 = 2

                                    $ B1_steel = 1

                                    #---------------ReturnV---------

                                    $ B1_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ B1 = 0

                                    $ B1_steel = 0

                                    $ B1_wood = 0

                                    jump forging_system_return



                        if result == "B2":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ B2 = 1

                                    $ B2_wood = 1

                                    #---------------ReturnV---------

                                    $ B2_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ B2 = 2

                                    $ B2_steel = 1

                                    #---------------ReturnV---------

                                    $ B2_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ B2 = 0

                                    $ B2_steel = 0

                                    $ B2_wood = 0

                                    jump forging_system_return



                        if result == "B3":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ B3 = 1

                                    $ B3_wood = 1

                                    #---------------ReturnV---------

                                    $ B3_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ B3 = 2

                                    $ B3_steel = 1

                                    #---------------ReturnV---------

                                    $ B3_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ B3 = 0

                                    $ B3_steel = 0

                                    $ B3_wood = 0

                                    jump forging_system_return



                        if result == "C1":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ C1 = 1

                                    $ C1_wood = 1

                                    #---------------ReturnV---------

                                    $ C1_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ C1 = 2

                                    $ C1_steel = 1

                                    #---------------ReturnV---------

                                    $ C1_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ C1 = 0

                                    $ C1_steel = 0

                                    $ C1_wood = 0

                                    jump forging_system_return



                        if result == "C2":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ C2 = 1

                                    $ C2_wood = 1

                                    #---------------ReturnV---------

                                    $ C2_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ C2 = 2

                                    $ C2_steel = 1

                                    #---------------ReturnV---------

                                    $ C2_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ C2 = 0

                                    $ C2_steel = 0

                                    $ C2_wood = 0

                                    jump forging_system_return



                        if result == "C3":

                            show bg forging_bag

                            menu:

                                "Was möchtest du einsetzen?"

                                "Holz":

                                    $ C3 = 1

                                    $ C3_wood = 1

                                    #---------------ReturnV---------

                                    $ C3_steel = 0

                                    jump forging_system_return

                                "Metal":

                                    $ C3 = 2

                                    $ C3_steel = 1

                                    #---------------ReturnV---------

                                    $ C3_wood = 0

                                    jump forging_system_return

                                "Material entfernen":

                                    $ C3 = 0

                                    $ C3_steel = 0

                                    $ C3_wood = 0

                                    jump forging_system_return




                        if result == "back":

                            jump forge1_start



                        if result == "forge":

                            menu:

                                "Möchtest du es wirklich schmieden?"

                                "Ja":

              #----------------------------------Rezepte-------------------------------------------------------------------


                                    #----------einfaches Stahlschwert---------------------------------------------------
                                    if A2 == 2:
                                        if B2 == 2:
                                            if C2 == 1:
                                                m "Wundervoll! Ein einfaches Stahlschwert."
                                                jump forging_system_return
                                            else:
                                                jump wrong_forging
                                        else:
                                            jump wrong_forging


                                    #----------einfaches Stahldolch---------------------------------------------------
                                    elif B2 == 2:
                                        if C2 == 1:
                                            m "Wundervoll! Ein einfacher Stahldolch."
                                            jump forging_system_return
                                        else:
                                            jump wrong_forging


                                    #----------einfaches SHarnisch---------------------------------------------------
              #                        elif A1 == 2:
              #                            if A3 == 2:
              #                                if B1 == 2:
              #                                    if B2 == 2:
              #                                        if B3 == 2:
              #                                            if C1 == 2:
              #                                                if C2 == 2:
              #                                                    if C3 == 2:
              #                                                        m "Exellent! Ein Vollstahlbrustharnisch."
              #                                                        jump forging_system_return
              #                                                    else:
              #                                                        jump wrong_forging
              #                                                else:
              #                                                    jump wrong_forging
              #                                            else:
              #                                                jump wrong_forging
              #                                        else:
              #                                            jump wrong_forging
              #                                    else:
              #                                        jump wrong_forging
              #                                else:
              #                                    jump wrong_forging
              #                            else:
              #                                jump wrong_forging



                                    elif A1 == 2 and A2 == 0 and A3 == 2:
                                        if B1 == 2 and B2 == 2 and B3 == 2:
                                            if C1 == 2 and C2 == 2 and C3 == 2:
                                                m "juhu"
                                                jump forging_system_return
                                            else:
                                                jump wrong_forging
                                        else:
                                            jump wrong_forging






                                    else:

                                        label wrong_forging:

                                            m "Hmm, Ich glaube das wird nichts."

                                            jump forging_system_return



                                "Nein":

                                        jump forging_system_return

I hope i didnt miss something - it in the middle of the night here >.<
Aaaaand i know, it might look messy to you, but thats what i have learned in about 3 days so far and still want to stay away from python.

please be nice to me :')

[Ocelot]

As I though, you code structured in a way which makes chestplate recipe impossible to trigger. Here is problem part of your code:

Code: Select all

elif B2 == 2: # !!!
    # some code
elif A1 == 2:
    # some code
        if B2 == 2:
              # more code
                  m "Exellent! Ein Vollstahlbrustharnisch."

THe only way you can craft chestplate is if B2 equals to 2. But, if B2 equals to 2, then condition, marked by !!!, triggers first, and control is transfered to the dagger block. Even if further checks for crafting a dagger fails, it does not return back to outward elif chain to contunue to try to match conditions.
The solution would be what trooper6 suggested: make all decidions in outward if-elif chain using logical operators.

And I would reconsider wanting to stay away from Pyrhon. If you are making something differen from generic VN and have some complex interactions, Python is immensively helpful. For example with a bit of Python code you would be able to do this:

Code: Select all

init python: 
    # You can define recipes in a single place in easier to understand way:
    recipes.add(
        Recipe(id='iron_sword', name='Stahlschwert', ingredients={'x':'iron', 'T':'stick'}, pattern=
            ' x '
            ' x '
            ' T '),
        Recipe(id='iron_dagger', name='Stahldolch', ingredients={'x':'iron', 'T':'stick'}, pattern=
            '   '
            ' x '
            ' T '),
        Recipe(id='iron_chestplate', name='Vollstahlbrustharnisch', ingredients={'x':'iron'}, pattern=
            'x x'
            'xxx'
            'xxx'),
    )

# later in crafting code:

# easy matching crafting grid to recipes with no chance of error
# you reuse same code, so as soon af you fixed that code
# you safe from errors in the future
$ result = recipes.match( [
    A1, A2, A3
    B1, B2, B3,
    C1, C2, C3
] )

if result is None:
    jump wrong_forging
elif result.id == 'iron_chestplate':
    m "Exellent! Ein Vollstahlbrustharnisch."
else:
    m "Wundervoll! Ein einfacher [result.name]."

[TraceOmega]

Thank you for your work.

I understand how it would work (somehow), but i have serious problems with using python because:

- I dont understand the way it operates. Means: I cant see where the python code is using the numeric values of the variables.
- As far as i see, you define 'iron' & 'stick' wich is great, but do i have to switch them for my named variables?
- And the third thing is, if i do it the way you showed me:
Is the programm able to consider the positions of the recipeparts by itself?

Im sorry for asking you that, but could you put your code working inbetween somewhere of my code, and show me what it would replace?
That acually would be my first time using python, and im scared to crash something.

[Ocelot]

The main question: did you get your current code working? Replacing all nested if statements (not only third chain, but previous two recipes too) with complex conditions would solve your problem.

If you have troubles replacing them: notice that

Code: Select all

if condition1:
    if condition2:

in most cases can be replaced with

Code: Select all

if condition1 and condition2:

About code I showed: it was just an example of how you can simplify your code by spending some time initially by setting everything up. My code is incomplete, it lacks Recipe and RecipeManager class definitions. If you are interested: part of my code starting with $ result = recipes.match( [ would replace everything from -Rezepte- to "Nein": (including recipes you did not add yet) and the rest of my code (including part I did not write) would go somewhere else. Probably into its own file.

I am not saying that you need to learn Python right now, but you should really consider to start learning it alongside your game development. It could greatly simplify your game code, make it easy to change, replace and enhance.

[TraceOmega]

Oh!
I finnaly understood the problem here.
Using 2 different systems was the problem | (Edit:) at the same time. You made me realize it.

By doing it the same way, written different it works perfectly:

Code: Select all

                        if A1 == 2 and A2 == 0 and A3 == 2 and B1 == 2 and B2 == 2 and B3 == 2 and C1 == 2 and C2 == 2 and C3 == 2:
                            m "Wunderbar, ein Stahlharnisch."
                            jump forging_system_return

                        elif A1 == 0 and A2 == 2 and A3 == 0 and B1 == 0 and B2 == 2 and B3 == 0 and C1 == 0 and C2 == 1 and C3 == 0:
                            m "Genial, ein einfaches Stahlschwert."
                            jump forging_system_return

                        elif A1 == 2 and A2 == 2 and A3 == 2 and B1 == 2 and B2 == 0 and B3 == 2 and C1 == 2 and C2 == 0 and C3 == 2:
                            m "Eine passende Stahlkettenhose, sehr Interessant."
                            jump forging_system_return

                        elif A1 == 0 and A2 == 0 and A3 == 0 and B1 == 0 and B2 == 2 and B3 == 0 and C1 == 0 and C2 == 1 and C3 == 0:
                            m "Sehr schön, ein einfacher Stahldolch."
                            jump forging_system_return

Thanks a bunch my friend - you really made my day.

Aaand yes, i will force myself into python a little bit.
It might look scary to me but everyone on the internet insists on it.

Thanks again to both of you and have a great day

[trooper6]

I've been fooling around with your problem for the last few days, and I have come up with what I think is a better version of what you are trying to do.

Check out this code:

Code: Select all

default sh = Item("Stahlharnisch", [2,0,2,2,2,2,2,2,2], "Wunderbar, ein Stahlharnisch.")
default ss = Item("Stahlschwert", [0,2,0,0,2,0,0,1,0], "Genial, ein einfaches Stahlschwert.")
default sk = Item("Stahlkettenhose", [2,2,2,2,0,2,2,0,2], "Eine passende Stahlkettenhose, sehr Interessant.")
default sd = Item("Stahldolch", [0,0,0,0,2,0,0,1,0], "Sehr schön, ein einfacher Stahldolch.")
default forged_inventory = [sh, ss, sk, sd]
default forged = False
default grid_pos = OrderedDict([('a1', 0), ('a2', 0), ('a3', 0), ('b1', 0), ('b2', 0), ('b3', 0), ('c1', 0), ('c2', 0), ('c3', 0)])

init -1 python:
    from collections import OrderedDict

    def increase(var):
        global grid_pos
        grid_pos[var] +=1
        if grid_pos[var] == 3:
            grid_pos[var] = 0
            
    def forge():
        global forged_inventory
        global grid_pos
        global forged
        grid_list = grid_pos.values()
        for i in forged_inventory:
            if i.recipe == grid_list:
                i.amount += 1
                renpy.notify("{0} You have {1}.".format(i.message, i.amount))
                renpy.hide_screen('forge_grid_sc')
                forged = True
        if not forged:
            renpy.notify("Hmm, Ich glaube das wird nichts.")
            
    class Item(object):
        def __init__(self, name, recipe, message, amount=0, **kwargs):
            self.name = name
            self.recipe = recipe
            self.message = message
            self.amount = amount
            
init python:
    for x in ["idle", "hover"]:
        for i in ["a1", "a2", "a3", "b1", "b2", "b3", "c1", "c2", "c3"]:
            renpy.image("{0}_{1}".format(i, x), ConditionSwitch(
                "grid_pos['{0}'] == 0".format(i), "images/mark_{0}.png".format(x),
                "grid_pos['{0}'] == 1".format(i), "images/wood_{0}.png".format(x),
                "grid_pos['{0}'] == 2".format(i), "images/steel_{0}.png".format(x)))

screen forge_grid_sc(): 
    vbox:
        xalign 0.5
        spacing 10
        grid 3 3:
            spacing 5
            for x in grid_pos.keys():
                frame:
                    imagebutton:
                        idle "{}_idle".format(x)
                        hover "{}_hover".format(x)
                        activate_sound 'click.wav'
                        action Function(increase, "{}".format(x))
        textbutton "Forge" action Function(forge) xalign 0.5 #here I should add the test of the recipes
                            
        
label shortcompscreen_test:   
    show screen forge_grid_sc()
    "Here is our forge grid screen.Make some choices then press the forge button"

    
    menu:
        "Go again?"
        "Yes":
            jump shortcompscreen_test
        "No":
            pass

    return