Making dialogue box fade in and out. [SOLVED]

[TellerFarsight]

Hi all,
I want to make it such that every time a new character speaks, the dialogue box very briefly fades out and back in, like in Devil Survivor. I think I should be able to fanaggle a way of doing it using window show and window hide statements, but is there some way to maybe bake that into the character definitions or into the whole UI?

[PyTom]

Here's a fairly complex character callback that does it.

Code: Select all

default last_character = None

init python:

    class WindowCallback(object):
        def __init__(self, name):
            self.name =  name

        def __call__(self, event, interact=True, **kwargs):

            global last_character

            if (not interact) or (event != "begin"):
                return

            if self.name == last_character:
                return

            if last_character is None:
                last_character = self.name
                return

            _window_hide(dissolve)
            _window_show(dissolve)

            last_character = self.name

define e = Character("Eileen", callback=WindowCallback("eileen"))
define l = Character("Lucy", callback=WindowCallback("lucy"))

[TellerFarsight]

NameError: name 'WindowCallback' is not defined

First of all, thanks a bunch PyTom for looking into this. I'm very new to Ren'Py and it's taking me a while to understand this, but this is the error I get back when trying to use it.
If it's not too much to ask, can you walk me through what I'm looking at here?

[Donmai]

You are probably defining your characters before the python block has run.

[TellerFarsight]

You are 100% correct and I can't believe I made that mistake. It totally works. Thanks!