Showing one screen hides another screen[SOLVED]

[TellerFarsight]

I have a button in the quick menu like this:

Code: Select all

screen quick_menu():
    zorder 100
    tag menu

    if quick_menu:
        imagemap:
            auto "gui/QuickMenu_%s.png"
            alpha False
            hotspot (221, 8, 39, 34) action Preference("auto-forward", "toggle")
            hotspot (265, 8, 39, 34) action Skip() alternate Skip(fast=True, confirm=True)
            hotspot (308, 8, 39, 34) action ShowMenu('history')
            if at_checkpoint:
                hotspot (380, 4, 52, 36) action ShowMenu('phone_menu')

The last button there goes to another screen called the phone menu:

Code: Select all

screen phone_menu():
    tag menu
    imagemap:
        auto "gui/PhoneMenu_%s.png"
        yalign 1.0
        alpha False
        hotspot (64, 348, 92, 116) action QuickSave()
        hotspot (176, 348, 92, 116) action ShowMenu('preferences')
        hotspot (288, 348, 92, 116) action Return()

Now, the problem is with another screen I have called the hud, which is displayed during dialogue and has the quick menu sitting on top of it. When I click the button to go to the phone menu, it brings up the phone menu but hides the hud screen. The phone menu is smaller than the screen, so the image doesn't actually cover up the hud screen. The hud screen is being hidden, but I want it not to.

Code: Select all

screen hud():
    style_prefix "hud"
    add "images/HUDstuff/HUD.png"
    add "ticker"
    add "colon"

[Ocelot]

IIRC ShowMenu hides all other screens. Try to use Show instead.

[TellerFarsight]

I tried that, but then the menu just didn't show up at all.

[Milkymalk]

Did you try "Show" with capital S? It's an action instead of a script statement, so you need to capitalize the first letter.

[TellerFarsight]

Yeah, and the phone menu didn't show up. It looked like the circle button just became a null action button. It's not because of the menu tags either because the two screens in question have different tags, and it's not because of zorder because that shouldn't affect a screen with a transparent hole in it.

[Milkymalk]

Could "alpha False" in the phone menu be at fault? Not sure what it does, but as you said the black bar is supposed to be transparent and transparency is made via alpha channel, this sounds like a possibility.

[TellerFarsight]

No, alpha here is about the hover area of the buttons, it doesn't affect the transparency of the top bar. It's showing black because the background image behind it is black up there.

[DannyGMaster]

Try the 'use' statement. In your quick_menu:

Code: Select all

default phone_on = False

screen quick_menu():
    zorder 100
    tag menu

    if quick_menu:
        if phone_on == True:
            use phone_menu()
        imagemap:
            auto "gui/QuickMenu_%s.png"
            alpha False
            hotspot (221, 8, 39, 34) action Preference("auto-forward", "toggle")
            hotspot (265, 8, 39, 34) action Skip() alternate Skip(fast=True, confirm=True)
            hotspot (308, 8, 39, 34) action ShowMenu('history')
            if at_checkpoint:
                hotspot (380, 4, 52, 36) action SetVariable('phone_on', True)

In theory (can't test without all those images) use should show the screen without hiding any other screen.

[vollschauer]

Don't use:

Code: Select all

tag menu

in your quick_menu/phone_menu

try to use:

Code: Select all

modal True

and use:

Code: Select all

... action Show('phone_menu')

[TellerFarsight]

That works! I had tried something similar before, but I had gone in the wrong direction; I was trying to have the phone_menu screen use the hud screen, your solution is better.

Any idea how to make the new screen come in with a fade or dissolve?

[TellerFarsight]

vollschauer, that also worked in fixing the display problem, but the phone_menu is also an imagemap, and using modal makes it so I can't interact with it.

Edit: Ok, I don't know what I did wrong last time but I tried your solution again and it worked. Thanks for your help everyone!