How to make textbuttons scrollable in viewport [SOLVED]

[Luxliev]

How can I make textbuttons scrollable? Text works fine but when I use textbuttons nothing moves.

Code: Select all

screen ui_inv:
    default equipment_counter = 0
    add "cs_bckg.png"
    
    textbutton "Close":
        xalign 1.0
        action Hide('ui_inv')

    vbox:
        area (800, 100, 430, 300)

        viewport id "vp_equipment":
            mousewheel True
            draggable True
            for equipment in party.inv:
                textbutton "[equipment.custom_name]":
                    ypos 30 * equipment_counter
                    action NullAction()
                $ equipment_counter += 1

        vbar value YScrollValue("vp_equipment")

init python:
    class Eq:
        def __init__(self, name):
            self.name = name
            self.custom_name = name
    
    Dirk = Eq("Dirk")
    Dagger = Eq("Dagger")
    Mace = Eq("Mace")        

    class PaD:
            def __init__(self):
                self.inv = []

            def add_equipment(self, *args):
                for element in args:
                    self.inv.append(element)
    
    party = PaD()
    party.add_equipment(Dirk, Dagger, Mace, Dirk, Dagger, Mace, Dirk, Dagger, Mace, Dirk, Dagger, Mace, Dirk, Dagger, Mace, Dirk, Dagger, Mace, Dirk, Dagger, Mace)
    


label start:
    show screen ui_inv
    "Hello, world."

    return

[Milkymalk]

Put it in a vbox (also note the scrollbars I added):

Code: Select all

        viewport id "vp_equipment":
            mousewheel True
            draggable True
            scrollbars "vertical"
            vbox:
                for equipment in party.inv:
                    textbutton "[equipment.custom_name]":
                        action NullAction()

[Luxliev]

Works great. Thanks for help