(SOLVED) Only show Quickmenu with Textbox

[theravano]

Hello!
Anyone knows a way to show my Quickmenu only when the textbox is on screen?

Here's my code, in screens.rpy

Code: Select all

screen quick_menu():

    zorder 100
    if quick_menu:
        hbox:
            style_prefix "quick"

            xalign 0.5
            yalign 1.0

         
            imagemap:
                ground 'GUI/quick menu/qm_ground.png'
                hover 'GUI/quick menu/qm_hover.png'
        
                alpha True
        
                hotspot (890,500,240,60) action Preference("auto-forward", "toggle") 
                hotspot (890, 540, 240, 60) action Skip()
                hotspot (890, 600, 240, 60) action ShowMenu("save")
                hotspot (890, 643, 240, 60) action ShowMenu("preferences")

                
init python:
    config.overlay_screens.append("quick_menu")

default quick_menu = True

style quick_button is default
style quick_button_text is button_text

style quick_button:
    properties gui.button_properties("quick_button")

style quick_button_text:
    properties gui.button_text_properties("quick_button")

There's a way to fuse it with the say screen or make it change/call it?
Thanks!

[Remix]

comment out:

Code: Select all

# init python:
#     config.overlay_screens.append("quick_menu")

alter screen say:

Code: Select all

screen say(who, what):
    style_prefix "say"

    window:
        id "window"

        if who is not None:

            window:
                style "namebox"
                text who id "who"

        text what id "what"
    
    # add this bit
    use quick_menu

Should work

[theravano]

Worked like a charm! Thank you!