"unicode object not callable" trying to have function argument specify which object is used in display [SOLVED]

[TellerFarsight]

Hey, so I'm trying to simplify some code. I had one branching set of screen menus for Marl attacking and one for Gorb attacking, but I assume I should be able to have one screen and use the arguments to specify whether Marl or Gorb is doing the attacking. Problem is, when I click on the button to show the "act_menu," it returns a "unicode object is not callable" error. Is it some syntax error or am I just completely thinking about this the wrong way?

Code: Select all

init -1 python:
    from random import randint
    class Unit(object):
        def __init__(self,name,hp,attack,defense):
            self.name = name
            self.hp = hp
            self.attack = attack
            self.defense = defense
        def damage(self, enemy):
            damage = randint(1,self.attack) - enemy.defense
            if damage >=0 and enemy.hp != "DEAD":
                enemy.hp = enemy.hp - damage
            if enemy.hp <=0:
                enemy.hp = "DEAD"
            
default Marl = Unit("Marl",100,20,1)
default Gorb = Unit("Gorb",100,10,2)

screen dudes():
    button:
        background Solid("ff0000")
        text "[Marl.hp]" align (0.5,0.5)
        xpos 200
        action Show("act_menu","Marl")
    button:
        background Solid("0000ff")
        text "[Gorb.hp]" align (0.5,0.5)
        xpos 600
        action Show("act_menu","Gorb")

screen act_menu(char):
    text "[char.name]" xpos 100 ypos 100
    text "Attack Power: [char.attack]" xpos 100 ypos 150
    text "Defense: [char.defense]" xpos 100 ypos 200
    textbutton "Attack!" action Show("select_target", "char")

screen select_target(char):
    text "Select Target!"
    textbutton "-->" action (Function([char].damage,Gorb), Hide("act_menu"), Hide("select_target"))
    textbutton "<--" action (Function([char].damage,Marl), Hide("act_menu"), Hide("select_target"))

[Remix]

It will be one (or all) of the lines where you are passing parameters as strings and then referencing them as objects... e.g.

Show( "screen_name_in_quotes_is_ok", variable_name_without_quotes_as_it_is_not_a_string )

[TellerFarsight]

I've tried that and the error is "Unit object is not callable"
The problem is where I'm trying to reference the objects. I was trying originally to pass them as strings and then reference them as strings which would then become the object, but now that I think about that it doesn't quite make sense.

[Remix]

The Function calls are likely the culprits... a standard char.damage rather than [char].damage should work.
The error output should tell you exactly which line is creating the glitch anyway

[TellerFarsight]

It looks like that's not the issue. I can't get the exact line of error because it's in a screen and it just points to the line in the script where I call the screen, but the error occurs only when I press this first button. I've also tried removing the parts where I call the attributes to be displayed. The problem is where I try to pass the Object name to the screen.

Code: Select all

screen dudes():
    button:
        background Solid("ff0000")
        text "[Marl.hp]" align (0.5,0.5)
        xpos 200
        action Show("act_menu",Marl)

screen act_menu(char):
    text "boo"

Even this code produces the same error.

[TellerFarsight]

I still can't figure it out. Is there a way a python object can be passed as a parameter to a screen?

[DannyGMaster]

I still can't figure it out. Is there a way a python object can be passed as a parameter to a screen?

Yes, the way you are doing it is just fine. The problem is the second argument of the Show action.

Show expects a string with the name of the screen, a transition, and then the arguments. In your code you are passing it the argument as the transition, therefore the error. Try:

Code: Select all

action Show('act_menu', None, Marl)

None, in this case, indicates that no transition should occur, but it can of course be substituted by any transition, like dissolve, but either way it should always follow the name of the screen, and be followed by any number of arguments you want to pass it.

[TellerFarsight]

You are so correct Danny!
I realize now why I didn't catch it. I have done code before that calls screens with arguments, but I went back and checked and I had done all of those with dictionaries. Using that same logic, this also worked:

Code: Select all

actions Show("act_menu", char=Marl)

[DannyGMaster]

this also worked:

Code: Select all

actions Show("act_menu", char=Marl)

Hey, I hadn't thought of that but it's actually a pretty nice idea, thank you!

Also glad I could help