[Solved] Screen action Show and kwargs issue

[backansi]

Code: Select all

init:
    $ morn = 'Rest'
    $ free = 'Rest'
    $ noon = 'Rest'
    
    screen planner: 
        
        vbox:
            align (.5, .5)
            grid 3 2:
                text 'Morning' 
                text 'BreakTime'
                text 'Afternoon'
                
                textbutton morn action Show('schedule', period='morn')
                textbutton free action Show('schedule', period='free')
                textbutton noon action Show('schedule', period='noon')
            textbutton 'Confirm' action Return()
                
    screen schedule(period):
        frame:
            align (.5, .8) 
            vbox: 
                textbutton 'Rest' action [SetVariable(period, 'Rest'), Hide('schedule')]
                textbutton 'Practicing' action [SetVariable(period, 'Practice'),Hide('schedule')]
                textbutton 'Planning Strategy' action [SetVariable(period, 'Planning Strategy'), Hide('schedule')]
                textbutton 'Mind Control' action [SetVariable(period, 'Mind Control'), Hide('schedule')]
                

label start:
    call screen planner

It seems show action with period 'free' and 'noon' does not work within my script.
Whenever I click any button in schedule screen only morn button changes its text.
I do not know what did I miss

[Divona]

It is strange, as period kwarg should pass the string to SetVariable... it just pass whatever the first kwarg set to... well, I came up with another way to do it:

EDIT: The issue seems to be a bug with Renpy version 6.99.12. It's fixed with version 6.99.13.

Code: Select all

default morn = 'Rest'
default free = 'Rest'
default noon = 'Rest'

init python:
    def set_schedule(period, value):
        global morn, free, noon

        if period == 'morn':
            morn = value

        if period == 'free':
            free = value

        if period == 'noon':
            noon = value

screen planner:

    vbox:
        align (.5, .5)
        grid 3 2:
            text 'Morning'
            text 'BreakTime'
            text 'Afternoon'

            textbutton morn action Show('schedule', period='morn')
            textbutton free action Show('schedule', period='free')
            textbutton noon action Show('schedule', period='noon')
        textbutton 'Confirm' action Return()

screen schedule(period):

    frame:
        align (.5, .8)
        vbox:
            textbutton 'Rest' action [Function(set_schedule, period, 'Rest'), Hide('schedule')]
            textbutton 'Practicing' action [Function(set_schedule, period, 'Practice'),Hide('schedule')]
            textbutton 'Planning Strategy' action [Function(set_schedule, period, 'Planning Strategy'), Hide('schedule')]
            textbutton 'Mind Control' action [Function(set_schedule, period, 'Mind Control'), Hide('schedule')]


label start:

    call screen planner

[backansi]

@Divona Thank you!