Load game problem (HELP PLS)

[riveralove]

Code: Select all

init python:
    
    locroom = 0
    hour = 12
    minut = 20
    
    def timelocation():
        global locroom, hour, minut   

        #locroom
        if hour >= 12 and hour <= 18:
            
            locroom = "room_sun1"
            
        elif hour >= 19 and hour <= 20:
        
            locroom = "room_sun2"
                
        elif hour >= 21 or hour <= 11:
            
            locroom = "room_sun3"
                
image room_sun1 = "backgrounds/room_sun1.png"
image room_sun2 = "backgrounds/room_sun2.png"
image room_sun3 = "backgrounds/room_sun3.png"

label room:
        $ timelocation()
        
        show screen room

screen room:
        add locroom

Everything works by code, the problem is that if you save the game and close it completely, the next time you load the save, it says that the variable $ locroom is not defined. Help me how to save these variables, where I read that such values are not saved.

Code: Select all

I'm sorry, but an uncaught exception occurred.

While running game code:
  File "renpy/common/000statements.rpy", line 485, in execute_call_screen
    store._return = renpy.call_screen(name, *args, **kwargs)
  File "game/script.rpy", line 65, in execute
    screen room:
  File "game/script.rpy", line 65, in execute
    screen room:
  File "game/script.rpy", line 67, in execute
    add locroom
Exception: Not a displayable: 0

Help please!

[IrinaLazareva]

Code: Select all

default hour = 12
default minut = 20
image room_sun = ConditionSwitch(
    "18>= hour >=12", "backgrounds/room_sun1.png",
    "20>= hour >=19", "backgrounds/room_sun2.png",
    "hour>=21 or hour <=11", "backgrounds/room_sun3.png",
    )
screen room:
    add "room_sun"
    
label room:
    show screen room
    
   
    "Test"
    $ hour = 20
    "20h"
    $ hour = 22
    "22h"
    $ hour = 13
    "13h"

doc: https://www.renpy.org/doc/html/displaya ... nSwitch