Ending based on time left?

[teamace]

I have a minigame on my VN that uses imagemaps (Find the missing object) wherein if the player finds the required item in less than 50s, it jumps to label scene1. Else, jumps to label scene2.

I'm still working on the timer before I continue working on the image map.
I'm not really good at coding but I get this error that says Invalid Syntax. I'm not really good at coding

init:
python:
def countdown(st, at, length=0.0):

remaining = length - st

if remaining >= 50.0:
return Text("%.1f" % remaining, color="#fff", size=72), .1
jump scene1
elif remaining < 50.0:
return Text("%.1f" % remaining, color="#f00", size=72), .1
jump scene2

# Show a countdown for 10 seconds.
image countdown = DynamicDisplayable(countdown, length=60.0)

label start:
"this is a text"
show countdown at Position(xalign=.1, yalign=.1)
"test"

label scene1:
"here"
label scene2:
"test"

[Empish]

Okay, so I think you're running into naming issues here. You have both a python function and an image named countdown. Try changing one of those names to be different. The second thing is, when you call a function you need to provide all the required parameters for it. It looks like you're just providing the length?

[Remix]

A version that works... might get you moving again

Code: Select all

init python:
    def countdown(st, at, length=0.0):
        global remaining
        remaining = length - st
        
        if remaining >= 10.0:
            return Text("[remaining:.1f]", color="#fff", size=72), .1

        if remaining <= 0.0:
            renpy.hide_screen( 'test' )
            renpy.jump( 'fail' )
        
        return Text("[remaining:.1f]", color="#f00", size=72), .1
                   
# default remaining = 15.0

screen test():
    vbox:
        add DynamicDisplayable(countdown, length=15.0)

        textbutton "Found Me":
            action [ Function(renpy.hide_screen, 'test'), Jump('found_me') ]

label start:
    "this is a text"
    call screen test
    "test"

label found_me:
    if remaining >= 10.0:
        jump scene1
    jump scene2
    
label scene1:
    "success fast"
    return

label scene2:
    "success slow..."
    return

label fail:
    "Too slow"
    return

You could alternatively use a Timer or Bar with AnimatedValue which could automate the expired time action a bit