how to stop my game when a variable is at a certain level ?

[squarecup]

Hello,

So I've a variable "alcool" and when this variable is equal to 100 I would like the game to jump to an end I've wrote, and this whenever we are in the game, its depend of the choice we make.

Is it possible ?

Thanks for your answer

[PyTom]

How is your game structured? You could check it using a python callback, but frankly that's probably more complicated than it needs be. I'd suggest one of two things. If you have a main loop the game returns to, you can just do:

Code: Select all

label mainloop:
    if alcool >= 100:
        jump ending

Otherwise, I'd suggest defining a function that modifies alcool for you. Something like:

Code: Select all

init python:
    def update_alcool(change):
        global alcool
        alcool += change
        if alcool >= 100:
             renpy.jump("ending")

And then use it instead of updating the variable directly.

Code: Select all

    $ update_alcool(+10)

[squarecup]

How is your game structured? You could check it using a python callback, but frankly that's probably more complicated than it needs be. I'd suggest one of two things. If you have a main loop the game returns to, you can just do:

Code: Select all

label mainloop:
    if alcool >= 100:
        jump ending

Otherwise, I'd suggest defining a function that modifies alcool for you. Something like:

Code: Select all

init python:
    def update_alcool(change):
        global alcool
        alcool += change
        if alcool >= 100:
             jump ending

And then use it instead of updating the variable directly.

Code: Select all

    $ update_alcool(+10)

Neither of them are working :/

[PyTom]

It isn't enough to say that they aren't working, you need to post an error message or say why.

[squarecup]

It's not that I have an error message, but when my variable alcool is > 100, the game continues

[Imperf3kt]

What did you put in the label called 'ending'?
Where did you put it?

You can remove all the dialogue and post the code if you want some more in-depth help.

[Remix]

Are you using
$ update_alcool( 5 )
or
$ alcool += 5
in the code?

Also, amend "jump ending" in the python function to something like "renpy.jump( 'ending' )"

[PyTom]

Yes, it was supposed to be renpy.jump("ending"). I've changed my example to fix that.

[squarecup]

Here's my code without the dialogue

ending.PNG (7.49 KiB) Viewed 998 times

Maybe i don't put the label where they need to be...

[Remix]

PyTom was using pseudo-code for the mainloop example ...
Probably better to try the other way (especially if not using a game loop approach):

Code: Select all

default alcool = 0

init python:
    def update_alcool(change):
        global alcool
        alcool += change
        if alcool >= 100:
             renpy.jump("ending")

label start:
    "..."
    $ update_alcool( 50 )
    "..."
    $ update_alcool( 50 )
    "we never get here"

label ending:
    "we do get here"
    return

P.S. Rather than attaching an image, it is much better to actually copy-paste your code with forum tags -- [code]Your code here[/code]

[squarecup]

I've tried your code and it's working perfectly ! Thank you so much !