How to force move mouse?

[AHAKuo]

I have seen this done on Doki Doki Literature Club when the mouse gets forcefully moved to a location.

How does it happen? How can I make the mouse move to a place by force?

[IrinaLazareva]

You can use MouseMove() action.
https://www.renpy.org/doc/html/screen_a ... #MouseMove

[AHAKuo]

You can use MouseMove() action.
https://www.renpy.org/doc/html/screen_a ... #MouseMove

Thanks for the response!

Hmm. And how would that code be implemented so that the mouse forcefully moves to a choice?

[ReDZiX]

Probably with something like this:

Code: Select all

#A WARNING: The x and y positions given are roughly the center of my screen,
#where I placed the exit button,
#you might have to test and change it to your own resolution for your game.

screen force_mouse_move():

    on "show":
        action MouseMove(x=650, y=350, duration=.3)

    timer .5 repeat True action MouseMove(x=650, y=350, duration=.3)

    textbutton "Click Me" xalign .5 yalign .5 action Return()

label start:
    scene black #Thi is just so I can see the button crearly

    call screen force_mouse_move

    "..."

[IrinaLazareva]

Hmm. And how would that code be implemented so that the mouse forcefully moves to a choice?

Just to select the value of coordinates.

One more example:

Code: Select all

screen myscreen():
    style_prefix 'choice'
    vbox:
        align(.5, .5)
        spacing 30
        textbutton "No" action NullAction()
        textbutton "Yep" action Hide('myscreen')        
        textbutton "Nope" action NullAction()    
    on 'show' action MouseMove(config.screen_width/2, config.screen_height/2, 3)

label start:
    '?'
    show screen myscreen
    '!'
    return

P.S. in an example the cursor is forced exactly on the center of the screen.

[MilywayObree]

You could do it like this...

Code: Select all

default currposition = 0
init python:
    def MoveMouseFunc():
        currposition = renpy.get_mouse_pos()
        tpos = [640, 345]
        if currposition[1] < tpos[1]:
            renpy.display.draw.set_mouse_pos((currposition[0] * 9 + tpos[0]) / 10.0, (currposition[1] * 9 + tpos[1]) / 10.0)

now define a screen to do this certain action...

Code: Select all

screen riggedmousescreen():
    timer 1.0/30.0 repeat True action Function(MoveMouseFunc)

once you did all of those...

Code: Select all

label start:
    show screen riggedmousescreen
    e "I am controlling your mouse"
    return

Hope it helped!

[AHAKuo]

Probably with something like this:

Code: Select all

#A WARNING: The x and y positions given are roughly the center of my screen,
#where I placed the exit button,
#you might have to test and change it to your own resolution for your game.

screen force_mouse_move():

    on "show":
        action MouseMove(x=650, y=350, duration=.3)

    timer .5 repeat True action MouseMove(x=650, y=350, duration=.3)

    textbutton "Click Me" xalign .5 yalign .5 action Return()

label start:
    scene black #Thi is just so I can see the button crearly

    call screen force_mouse_move

    "..."

OMG THIS IS THE BEST CODE!

Thank you so much for this help! It really saved me BIG THANKS! <3