Changing dialogue statement [SOLVED]

[Potato0095]

Hi!

I wanted to know how to write this code:

Code: Select all

"\"Hey, what are you doing?\""

Like this:

Code: Select all

"Hey, what are you doing?"

And still have the " " in the text. I've been searching through some VN's codes, and Doki Doki does have this feature, so there's a way to do it likewise, right? (the problem is: I don't know how to do it).

[Draziya]

If you want to do "\"Hey, what are you doing?\"" without doing the backslash every time you would do it like this:

Code: Select all

define e = Character("Eileen", what_prefix='"', what_suffix='"')

If you want to do something like "\"Hey, what are you doing?\" said Eileen." without doing the backslash every time you would use " " for one of them, and ' ' for the other.

[Potato0095]

Welp, it works like you said, thanks.

[Remix]

If you are using it sporadically (just sometimes for some characters) you could also use a Creator Defined Statement
The example does exactly what you wanted, just remember it must be defined in a python early in a separate file (preferably with name starting 01)

Creator-defined statements allow you to add your own statements to Ren'Py. This makes it possible to add things that are not supported by the current syntax of Ren'Py.

Creator-defined statements must be defined in a python early block. What's more, the filename containing the user-defined statement must be be loaded earlier than any file that uses it. Since Ren'Py loads files in unicode sort order, it generally makes sense to prefix the name of any file containing a user-defined statement with 01, or some other small number.

A user-defined statement cannot be used in the file in which it is defined.

Creator-defined statement are registered using the renpy.register_statement function.

The Example

Code: Select all

python early:

    def parse_smartline(lex):
        who = lex.simple_expression()
        what = lex.rest()
        return (who, what)

    def execute_smartline(o):
        who, what = o
        renpy.say(eval(who), what)

    def lint_smartline(o):
        who, what = o
        try:
            eval(who)
        except:
            renpy.error("Character not defined: %s" % who)

        tte = renpy.check_text_tags(what)
        if tte:
            renpy.error(tte)

    renpy.register_statement("line", parse=parse_smartline, execute=execute_smartline, lint=lint_smartline)

This can be used by writing:

Code: Select all

line e "These quotes will show up," Eileen said, "and don't need to be backslashed."

Which outputs:
"These quotes will show up," Eileen said, "and don't need to be backslashed."