[Solved]Can I use 'hide' with transforms and 'at'?

[Nazon]

If I want to show character sprite with "fading in from nowhere" effect I use transform:

Code: Select all

transform fadein_from_right:
    ease 0.0 xoffset 10 alpha 0.0
    ease 0.5 xoffset 0 alpha 1.0

Code: Select all

show eileen at fadein_from_right

But how I can make a charater sprite to move slightly to the right and hide?

The command

Code: Select all

transform fadeout_to_right:
    ease 0.5 xoffset 10 alpha 0.0

hide eileen at fadeout_to_right

doesn't work, the sprite just dissappears without effect.

Is it possible to use transforms with 'hide' ?

[Milkymalk]

You can use the "on" statement to tell Ren'Py to apply a certain ATL block when something is shown or hidden:
https://www.renpy.org/doc/html/atl.html#on-statement

[Nazon]

You can use the "on" statement to tell Ren'Py to apply a certain ATL block when something is shown or hidden:
https://www.renpy.org/doc/html/atl.html#on-statement

Thank you.
Yes, but in that case, I need to specify this 'on hide' command in a 'show' statement.
Something like this:

Code: Select all

transform fadeout_to_right:
    ease 0.5 xoffset 10 alpha 0.0

Code: Select all

show eileen:
        on hide:
            fadeout_to_right

"Good bye!"

hide eileen

But what if I can't use 'on hide' with the 'show' command and have to mention my transform effect only with a 'hide' command? (Special circumstances.)

I also tried

Code: Select all

hide eileen:
      on hide:
            fadeout_to_right

but it doesn't work this way.

[Milkymalk]

Why is it that you can't use 'on' with the 'show' statement?

You can also include 'on hide' inside a transform:

Code: Select all

transform fade_and_slide:  
    on show:
	 ease 0.0 xoffset 10 alpha 0.0
	 ease 0.5 xoffset 0 alpha 1.0
    on hide:
        ease 0.5 xoffset 10 alpha 0.0
        
label start:
    show eileen at fade_and_slide

[Ocelot]

I believe, the idea is to use different animations in different cases:

Code: Select all

show eileen
e "Let's split up and search this haunted house alone!"
e "Where should I go?"
menu:
    "To the left":
        hide eileen # should exit left
    "To the right":
        hide eileen # should exit right

I would consider using transitions here: https://www.renpy.org/doc/html/transitions.html
In particular Dissolve, Move and ComposeTransition. Maybe you would have to define your own. Sadly documentatio on defining your own transition is nonexistent, so you will have to figure it out yourself.

[Nazon]

Why is it that you can't use 'on' with the 'show' statement?

You can also include 'on hide' inside a transform:

Code: Select all

transform fade_and_slide:  
    on show:
	 ease 0.0 xoffset 10 alpha 0.0
	 ease 0.5 xoffset 0 alpha 1.0
    on hide:
        ease 0.5 xoffset 10 alpha 0.0
        
label start:
    show eileen at fade_and_slide

Well, it's a long story...
Yes, I can include 'on hide' in the first transform block, but unfortunatelly there should be two separate blocks. One for 'show' transform and another for 'hide'.

I believe, the idea is to use different animations in different cases:

Not exactly, but something like this.

I would consider using transitions here: https://www.renpy.org/doc/html/transitions.html

Sure, I also tried to perform 'with mycomposetransition' , but I couldn't create a transition that would do the same effects as the transform block.

So, as a workaround I am using another 'show' statement:

Code: Select all

transform fadein_from_right:
    ease 0.0 xoffset 10 alpha 0.0
    ease 0.5 xoffset 0 alpha 1.0

Code: Select all

transform fadeout_to_right:
    on hide:    
        ease 0.5 xoffset 10 alpha 0.0

Code: Select all

show eileen at fadein_from_right
"Hello."
"And good bye."
show eileen at fadeout_to_right #As far as I understand, this would not show the same image two times, but will change transition to 'fadeout_to_right'
hide eileen #Now the image would be hidden with 'fadeout_to_right' effect