[SOLVED] If Statement and Variables Not Working

[codenewbie]

Hello! I'm new to both Ren'Py and coding. I'm trying to work with an if statement and variables. I want the player to go through all three menu choices before being able to move on with the game. So far, I have the following code, but the game just loops the menu over and over again.

Code: Select all

    define memCount = 0 #when memCount = total # of mems in the room, can move on

    scene bg dining room
    if memCount == 3:
        "all three memories collected"
        return
    else:
        menu DiningRoom:
            with Dissolve(1.0)
            "Fish":
                jump fish
            "Cat Painting":
                jump catpainting
            "Plant":
                jump plant

        label fish:
            $ memCount += 1 #increment memory count
            "fish"
            jump DiningRoom

        label catpainting:
            $ memCount += 1 #increment memory count
            "cat painting"
            jump DiningRoom

        label plant:
            $ memCount += 1 #increment memory count
            "plant"
            jump DiningRoom

Thank you!

[trooper6]

Put this in a new project and check it out.

Code: Select all

# Define varbles
default hasFish = False
default hasCat = False
default hasPlant = False

# The game starts here.

label start():
    "Your game has started."
    
    menu diningRoom:
        "Think on memories?"
        "Fish" if not hasFish:
            jump fish
        "Cat Painting" if not hasCat:
            jump catpainting
        "Plant" if not hasPlant:
            jump plant
        "All three memories collected. Continue on." if hasFish and hasCat and hasPlant:
            jump theNextScene

    return

label fish():
    $hasFish = True
    "Fish"
    jump diningRoom

label catpainting():
    $hasCat = True
    "cat painting"
    jump diningRoom

label plant():
    $hasPlant = True
    "plant"
    jump diningRoom

label theNextScene():
    "The game continues on."
    return

[Ocelot]

In addition to trooper6 answer: Source of your problem is your jumps aftermenu item labels. You are jumping directly to menu, completely skipping check for memory.

[codenewbie]

I see! Thank you both for your help!