[SOLVED] List of days cycles only through Sunday to Monday

[tapanojum]

Hi, I'm having issues getting my days to cycle.

Code: Select all

init:
    default days = 0

screen ui_text:
    if 0 <= float(minn/60)%24 < 1:
        $ days = days + 1
    $ day_num = (days % 7)
    $ day_name = ('Sun', 'Mon', 'Tue', 'Wed', 'Thu', ' Fri', 'Sat')
    $ day = day_name[day_num]
    zorder 101
    text "[day]"  size 36 color "#ffffff" font "IndieFlower-Regular.ttf" xpos 31 ypos 27
    text hour()  size 32 color "#ffffff" font "IndieFlower-Regular.ttf" xpos 110 ypos 32

So once the clock goes past midnight, days should continue from Sunday to Saturday. Instead what happens is that Sunday turns to Monday at midnight -1am, and then turns back to Sunday after 1am.

The culprit behind this is that the variable days never changes from anything but 0. Any ideas whats going on?

[kivik]

A couple of things wrong with your code:

1 - don't put default inside an init block. default goes outside any blocks.
2 - Don't put the logic inside your screen - screens should only display your data, you should have separate functions or classes to manage your data (your day and time).

With that in mind, either create a function that updates your days and day variable, or better yet, create a daytime class object to manage it. There should be some examples in the forum already but you seem to have the general idea of how to do it, so I'm sure you can work it out.

If you struggle with anything, post your updated code and we can give you more pointers

[xavimat]

Some explanations:

1. Is not actually wrong, is useless, because renpy knows that "default" will be executed at init phase.

2. The problem here is the prediction system. Renpy will predict what to show in a screen before it's actually showed to avoid glitches with complex screens. This prediction will happen an undetermined number of times. So, the screen should never contain side effects like changing global variables (your line $ days = days + 1 does that).

[tapanojum]

Thank you Kivik and Xavimat. I implemented your suggestions and the code is working correctly. For anyone curious for the solution:

Code: Select all

def which_day(day=0):

        global days
        day_num = (days % 7)
        day_name = ('Sun', 'Mon', 'Tue', 'Wed', 'Thu', ' Fri', 'Sat')
        day = day_name[day_num]
        return day

and then on the screen it calls the function.

Code: Select all

screen ui_text:
    zorder 101
    text which_day()  size 36 color "#ffffff" font "IndieFlower-Regular.ttf" xpos 31 ypos 27
    text hour()  size 32 color "#ffffff" font "IndieFlower-Regular.ttf" xpos 110 ypos 32

I am now having issues with the logic for keeping track of days. I have a 24 hour time system in place. Whenever it's passed midnight, I want the days to +1. I have two buttons that allows the players to pass time, either at 30m increment or 12 hours. My first draft of the code added a day whenever the clock struck midnight.

Code: Select all

if float(minn%1440) == 0:
            days = days + 1
            return days

However, if the player uses the +12 hours button, they can skip midnight all together and the day will not advance. Any ideas of how I can implement days to advance after a full 24h cycle?

Thank you again!

[xavimat]

I always use a while loop for time passing. I use a function too:

Code: Select all

default minute = 0
default hour = 0
default day = 0
init python:
    def tempus_fugit(m, h=0, d=0):
        global minute, hour, day
        minute += m
        hour += h
        day += d
        while minute > 59:
            hour += 1
            minute -= 60
        while hour > 23:
            day += 1
            hour -= 24

[tapanojum]

Xavimat, thank you for your reply. That is such a simple and perfect solution. I have no idea why I couldn't think of it. I kept messing with modulo when this works so much better.

Thanks again!