[Solved] Ending credits skipable after seen once

[kostek00]

I made ending credits that are shown after game has been beated. I don't want to force users to watch them everytime they beat game but I want them to see them once. After that I want to allow users to skip them.

Code: Select all

if ???:
    $ renpy.pause(delay=60, hard=False)
else:
    $ renpy.pause(delay=60, hard=True)

I just don't know what can I use in place "???" to achieve this.

I found in documentation renpy.is_seen and renpy.seen_label but didn't found examples how to use them.

Does this would work as I would like?

Code: Select all

if renpy.is_seen(ever=True):
    $ renpy.pause(delay=60, hard=False)
else:
    $ renpy.pause(delay=60, hard=True)

label ending:
scene black with None
show credits
play music "bgm/M08.ogg" fadein 1.0
$ renpy.pause(delay=60, hard=True)
stop music fadeout 1.0
pause 1.0
I'm also using label to show ending credits but I'm thinking about jumping/calling screen here that will show ending credits. The reason for that is to remove any shortcuts while ending credits are shown.

[Donmai]

Personally, I believe credits should be always skippable. Forcing players to do things is the best way to make them look for a more friendly game to play. Anyway, that's your game and your audience . You will find some ideas in this thread (discussion on this topic start around post #13: viewtopic.php?f=51&t=22481

[kivik]

Why not just use a persistent variable?

[kostek00]

I don't know how to use them.

@Donmai I also consider making them not skipable for only the 1-2 seconds just to be sure that they aren't accidently skipped and after that allow.

[Imperf3kt]

As an example, you could do it like this:

Code: Select all

default persistent.creds_seen = "False"
label start:
    "this game is really short."
    call my_credits
    return

label my_credits:
    scene black with None
    show credits
    play music "bgm/M08.ogg" fadein 1.0
    if persistent.creds_seen:
        $ renpy.pause(delay=3, hard=True)
        $ renpy.pause(delay=57, hard=False)
    else:
        $ renpy.pause(delay=60, hard=True)

    stop music fadeout 1.0
    pause 1.0
    return

Personally, I would not do this, I'd make the hard pause more like 15 seconds at the most.

[Remix]

As an example, you could do it like this:

... adjustments

Code: Select all

default persistent.creds_seen = False # boolean not string
label start:
    "this game is really short."
    call my_credits
    return

label my_credits:
    scene black with None
    show credits
    play music "bgm/M08.ogg" fadein 1.0
    
    # 5 secs hard pause on first viewing
    $ renpy.pause(delay=5, hard=not persistent.creds_seen)
    
    # remainder skippable even on first view
    $ renpy.pause(delay=55, hard=False)
    
    $ persistent.creds_seen = True # <-- set the persistent

    stop music fadeout 1.0
    pause 1.0
    return

[Imperf3kt]

...
Thanks for fixing it up. I was half asleep when I wrote it out xD
I knew something wasn't right, but half-asleep me didn't see anything.

[kostek00]

Thank you all for help.

If I'm not lying myself I think I'm starting to understand persistent variables. I readed in documentation they can be used for gallery unlocking. And if for gallery then for replays as well. I didn't tested when exacly replays are unlocked whether right after hitting replay label or replay end but based on what it says in documentation I assume it's right after hitting label and that's not correct because user shouldn't see replay is he didn't seen whole scene in that replay. It doesn't make sense. To make sure it's unlocking when it should changing this code:

Code: Select all

            imagebutton:
                insensitive "images/thumbnails/thumbnail_insensitive.png"
                idle "images/thumbnails/thumbnail01.png"
                idle_foreground Solid((0,0,0, 100))
                hover "images/thumbnails/thumbnail01.png"
                action Replay("replay1", locked=None)
                pos(220,170)
                
label replay1:
    #dialogs
    $ renpy.end_replay()

To this should do the trick, right?

Code: Select all

            imagebutton:
                insensitive "images/thumbnails/thumbnail_insensitive.png"
                idle "images/thumbnails/thumbnail01.png"
                idle_foreground Solid((0,0,0, 100))
                hover "images/thumbnails/thumbnail01.png"
                action Replay("replay1", locked=not persistent.replay1)
                pos(220,170)

label replay1:
    #dialogs
    $ renpy.end_replay()
    $ persistent.replay1

Or does "$ persistent.replay1" needs to be "$ persistent.replay1 = True"?

[Remix]

Not really dabbled with replays as yet, though for the variables, if you are assigning a value to the variable you always use " variable = value "
If you are conditionally testing them you *can* use " if variable: " for cases such as (True, non zero integers or floats, non empty list, dict or string)

[kostek00]

Code: Select all

            imagebutton:
                insensitive "images/thumbnails/thumbnail_insensitive.png"
                idle "images/thumbnails/thumbnail01.png"
                idle_foreground Solid((0,0,0, 100))
                hover "images/thumbnails/thumbnail01.png"
                action Replay("replay1", locked=not persistent.replay1)
                pos(220,170)

label replay1:
    #dialogs
    $ renpy.end_replay()
    $ persistent.replay1 = True

This worked as I wanted. Thanks for help.